USACO 2014 JAN 滑雪录像{silver题3}

滑雪录像{silver题3}

【问题描述】

   冬奥会的电视时刻表包含N (1 <= N <= 150)个节目，每个节目都有开始和结束时间。农民约翰有两台录像机，请计算他最多可以录制多少个节目。

【文件输入】

第一行，一个整数N。

接下来N行每行两个整数，表示一个节目的开始和结束时间，范围为0..1,000,000,000。

【文件输出】

一个整数，表示最多可以录制的节目数量。

【输入样例】

6

0 3

6 7

3 10

1 5

2 8

1 9

【输出样例】

4

【样例说明】

第1台录制节目1和3，第2台录制节目2和4。

思路：一开始觉得用两次DP，第一次DP得出最优解，之后将最优解删去，再DP，最后得出的就是答案，但是本题由于两个录像可能会有覆盖，这样两次DP就需要有特判，然后特判很烦，也就没打，只有70分。后来得知本题原来可以贪心，我也是醉了、、、先将结束时间进行排序，然后记录两台录像机当前最后一个的结束时间，如果一个录像只能由一台相机录，那就给它录，如果两台录像机都可以录此录像，那么就选两台录像机中结束时间晚的那个来录它（至于为什么，也不用说了，自己想）。接下来上代码

var
s,t:array[0..150]of longint;
i,n,t1,t2,ans:longint;

procedure openit;
 begin
  assign(input,'recording.in');assign(output,'recording.out');
  reset(input);rewrite(output);
 end;

procedure closeit;
 begin
  close(input);close(output);
 end;

procedure qsort(l,r:longint);
 var i,j,m,temp:longint;
  begin
   i:=l;j:=r;m:=t[(l+r) div 2];
   repeat
    while t[i]<m do inc(i);
    while t[j]>m do dec(j);
    if not (i>j) then
     begin
      temp:=s[i];s[i]:=s[j];s[j]:=temp;
      temp:=t[i];t[i]:=t[j];t[j]:=temp;
      inc(i);dec(j);
     end;
   until i>j;
   if l<j then qsort(l,j);
   if i<r then qsort(i,r);
  end;


begin
 openit;
 readln(n);
 for i:=1 to n do readln(s[i],t[i]);
 qsort(1,n);      //快排结束时间
 t1:=0;t2:=0;ans:=0;
 for i:=1 to n do
  begin
   if (s[i]>=t1) and (s[i]>=t2) then
    begin
     inc(ans);
     if t1>t2 then t1:=t[i]
              else t2:=t[i];
     continue;
    end;
   if s[i]>=t1 then begin inc(ans);t1:=t[i]; end;
   if s[i]>=t2 then begin inc(ans);t2:=t[i]; end;
  end;
 writeln(ans);
 closeit;
end.