USACO 2014 FEB自动打字{Silver题1}

自动打字{Silver题1}

【问题描述】

贝西新买了手机，打字不方便，请设计一款应用，帮助她快速发消息。

字典里有W（W<=30000）个小写字母构成的单词，所有单词的字符总数量不超过1,000,000，这些单词是无序的。现在给出N(1 <= N <= 1000)个询问，每个询问i包含一个的字符串s_i（每个字符串最多包含1000个字符）和一个整数K_i，对于所有以s_i为前缀的单词，其中按字典序排序后的第K_i个单词，求该单词在原字典里的序号。

【文件输入】

第一行为两个整数W和N。

接下来2..W+1行，每行一个单词；

接下来W+2..W+N+1行，一个整数和一个字符串，分别表示K_i和s_i。

【文件输出】

   输出共N行，每行一个整数，表示位置，如果无解则输出-1。

【输入样例】

10 3

dab

ba

ab

daa

aa

aaa

aab

abc

ac

dadba

4 a

2 da

4 da

【输出样例】

3

1

-1

【样例说明】

以a为前缀的单词有{aa,aaa,aab,ab,abc,ac}，第4个是ab，它在原字典中的位置是3，以da为前缀的单词有{daa,dab,dadba}，第2个是dab，它在原字典中的位置是1，以da为前缀的第4个单词不存在。

思路：本题一开始听闻要使用trie树，结果后来发现原来不用trie树也可以AC。首先快排字符串，然后将以各个字母为开头的起始和终点处理出来，然后枚举就可以AC了。代码如下

var
str:array[0..30000]of string;
s,e:array['a'..'z']of longint;                    //以各个字母为开头的起点和终点
num:array[0..30000]of integer;
w,n,i,j,k:longint;
temp:string;
ch:char;

procedure openit;
 begin
  assign(input,'auto.in');assign(output,'auto.out');
  reset(input);rewrite(output);
 end;

procedure closeit;
 begin
  close(input);close(output);
 end;

procedure qsort(l,r:longint);                 //快排字符串
 var i,j,p:longint;
     m,q:ansistring;
  begin
   i:=l;j:=r;m:=str[(l+r) div 2];
   repeat
    while str[i]<m do inc(i);
    while str[j]>m do dec(j);
    if not (i>j) then
     begin
      q:=str[i];str[i]:=str[j];str[j]:=q;
      p:=num[i];num[i]:=num[j];num[j]:=p;
      inc(i);dec(j);
     end;
   until i>j;
   if l<j then qsort(l,j);
   if i<r then qsort(i,r);
  end;

procedure datain;
 var i:longint;
  begin
   readln(w,n);
   for i:=1 to w do readln(str[i]);
   for i:=1 to w do num[i]:=i;
   qsort(1,w);
   k:=2;ch:=str[1,1];s[ch]:=1;e[ch]:=1;
   while k<=w do
    begin
     if str[k,1]<>ch then begin
                           ch:=str[k,1];
                           s[ch]:=k;e[ch]:=k;
                          end
                     else inc(e[ch]);
     inc(k);
    end;
  end;


begin
 openit;
 datain;
 for i:=1 to n do
  begin
   readln(k,ch,temp);
   for j:=s[temp[1]] to e[temp[1]] do                   //枚举
    if str[j]>=temp then break;
   if (j+k-1>w) or (length(str[j+k-1])<length(temp)) then
    begin
     writeln('-1');
     continue;
    end;
   j:=j+k-1;
   if copy(str[j],1,length(temp))=temp then writeln(num[j])
                                       else writeln('-1');
  end;
 closeit;
end.