表modifiedField方法使用例子

public void modifiedField(fieldId _fieldId)
{
    super(_fieldId);

    switch (fieldExt2Id(_fieldId))
    {
        case fieldnum(InventTable, ItemId):
            this.ItemName   = this.ItemName ? this.ItemName : this.ItemId;
            this.setNameAlias();
            break;

        case fieldnum(InventTable, ItemName):
            this.NameAlias  = '';
            this.setNameAlias();
            break;

        case fieldnum(InventTable, AltItemId):
            this.AltConfigId         = '';
            this.AltInventColorId    = '';
            this.AltInventSizeId     = '';
            break;

        case fieldnum(InventTable, Phantom):
            if (this.Phantom)
                this.AutoReportFinished = NoYes::No;
            break;

        case fieldnum(InventTable, OrigCountryRegionId):
            this.OrigStateId = '';
            break;

        case fieldnum(InventTable, PBAAutoStart):
            if (this.PBAAutoStart)
                this.PBAMandatoryConfig = NoYes::No;
            break;

        case fieldnum(InventTable, PBAMandatoryConfig):
            if (this.PBAMandatoryConfig)
                this.PBAAutoStart = NoYes::No;
            break;

        case fieldnum(InventTable, ItemType):
            if (this.ItemType == ItemType::Service)
            {
                this.FiscalLIFOAvoidCalc = NoYes::Yes;
                this.PalletTagging       = NoYes::No;
                this.ItemTaggingLevel    = RFIDItemTaggingLevel::None;
            }
            break;

        case fieldnum(InventTable, MinAverageSettle):
            if (this.MinAverageSettle < 0.1 && !this.MinAverageSettle == 0)
                warning("@SYS96741");
            if (this.MinAverageSettle < 0 && !this.MinAverageSettle == 0)
                this.MinAverageSettle = 0.1;
            break;
    }
}