bzoj1835

最近状态太差，先补补结题报告吧
这是一道好题
设f[i,j]表示到第j个位置建了i个基站且第j个位置建了基站的最小花费
不难得到f[i,j]=min(f[i-1,k]+cost[k+1,j])+c[j];
首先为了方便计算假定在两端无穷远处还要建一个基站（方便统计）
i我们是可以滚动的不管他，问题就是如何解决cost
也就是两个基站间的村庄的补偿费
我们设每个村庄i向左最远能收到l[i]位置上基站的信号，向右最远r[i]
不难发现，随着j的递增，cost[k]是呈上升趋势的
也就是，对于当前j，那些r[p]<j的点p，向右是永远收不到信号了，
向左对于在位置k∈[0,l[p]-1]的基站，随着j增加以k,j为端点建基站对于p是永远要收补偿费的
于是我们令cost[k]表示（k建基站）到当前点之间村庄要收补偿费的和
对于当前点j，我们找出r[p]+1=j的点p，对于k∈[0,l[p]-1] cost[k]+w[p]
显然是区间查询，区间修改的问题，我们可以用线段树解决
复杂度O(knlogn)

type node=record
       po,next:longint;
     end;

var f,c,d,p,w,s,l:array[0..20010] of longint;
    e:array[0..20010] of node;
    tree,lazy:array[0..20010*4] of longint;
    ans,n,m,i,j,k,t,x:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure update(i:longint);
  begin
    tree[i]:=min(tree[i*2],tree[i*2+1]);
  end;

procedure push(i:longint);
  begin
    inc(lazy[i*2],lazy[i]);
    inc(lazy[i*2+1],lazy[i]);
    inc(tree[i*2],lazy[i]);
    inc(tree[i*2+1],lazy[i]);
    lazy[i]:=0;
  end;

function fl(l,r,x:longint):longint;
  var m:longint;
  begin
    fl:=r;
    while l<=r do
    begin
      m:=(l+r) shr 1;
      if d[m]>=x then
      begin
        fl:=m;
        r:=m-1;
      end
      else l:=m+1;
    end;
  end;

function fr(l,r,x:longint):longint;
  var m:longint;
  begin
    fr:=l;
    while l<=r do
    begin
      m:=(l+r) shr 1;
      if d[m]<=x then
      begin
        fr:=m;
        l:=m+1;
      end
      else r:=m-1;
    end;
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    lazy[i]:=0;
    if l=r then
    begin
      tree[i]:=f[l];
      lazy[i]:=0;
    end
    else begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
      update(i);
    end;
  end;

procedure work(i,l,r,x,y:longint);
  var m:longint;
  begin
    if r<=x then
    begin
      inc(lazy[i],y);
      inc(tree[i],y);
    end
    else begin
      if lazy[i]<>0 then push(i);
      m:=(l+r) shr 1;
      work(i*2,l,m,x,y);
      if x>m then work(i*2+1,m+1,r,x,y);
      update(i);
    end;
  end;

function ask(i,l,r,x:longint):longint;
  var m,s:longint;
  begin
    if r<=x then exit(tree[i])
    else begin
      if lazy[i]<>0 then push(i);
      m:=(l+r) shr 1;
      s:=ask(i*2,l,m,x);
      if x>m then s:=min(s,ask(i*2+1,m+1,r,x));
      exit(s);
    end;
  end;

begin
  readln(n,m);
  for i:=2 to n do
    read(d[i]);
  for i:=1 to n do
    read(c[i]);
  for i:=1 to n do
    read(s[i]);
  for i:=1 to n do
  begin
    read(w[i]);
    ans:=ans+w[i];
  end;
  for i:=1 to n do
  begin
    l[i]:=fl(1,i,d[i]-s[i]);
    x:=fr(i,n,d[i]+s[i]);
    inc(t);
    e[t].po:=i;
    e[t].next:=p[x+1];
    p[x+1]:=t;
  end;
  for i:=1 to m do
  begin
    build(1,0,n);
    for j:=1 to n+1 do
    begin
      k:=p[j];
      while k<>0 do
      begin
        work(1,0,n,l[e[k].po]-1,w[e[k].po]);
        k:=e[k].next;
      end;
      if i=1 then x:=0 else x:=j-1;
      f[j]:=ask(1,0,n,x)+c[j];
    end;
    ans:=min(ans,f[n+1]);
  end;
  build(1,0,n);
  for j:=1 to n+1 do
  begin
    k:=p[j];
    while k<>0 do
    begin
      work(1,0,n,l[e[k].po]-1,w[e[k].po]);
      k:=e[k].next;
    end;
  end;
  ans:=min(ans,ask(1,0,n,n));
  writeln(ans);
end.