bzoj1014

动态询问LCP，所以我们不好用后缀数组
考虑使用维护序列问题的splay+hash求LCP
这里mark一下，hash求LCP常用mo=9875321
自然溢出的话交上去莫名其妙WA了
这里树上某节点hash值代表的是这棵子树所代表的序列hash值
求LCP时，只要二分答案然后提取区间判断hash是否相同即可,实践证明错误率很小
这里注意要尽量少取模运算，否则会TLE

const mo=9875321;
var son:array[-1..100010,1..2] of longint;
    count,fa,hash,a:array[-1..100010] of longint;
    d:array[0..100010] of longint;
    m,n,root,i,x,y,s:longint;
    ch:char;

procedure update(x:longint);
  var l,r:longint;
  begin
    l:=son[x,1];
    r:=son[x,2];
    count[x]:=count[l]+count[r]+1;
    hash[x]:=hash[l]+a[x]*d[count[l]]+int64(hash[r])*int64(d[count[l]+1]) mod mo;  //计算hash
    hash[x]:=hash[x] mod mo;
  end;

function find(k:longint):longint;
  var p:longint;
  begin
    p:=root;
    while true do
    begin
      if count[son[p,1]]+1=k then exit(p);
      if count[son[p,1]]+1>k then p:=son[p,1]
      else begin
        k:=k-count[son[p,1]]-1;
        p:=son[p,2];
      end;
    end;
  end;

procedure rotate(x,w:longint);
  var y:longint;
  begin
    y:=fa[x];
    if fa[y]<>-1 then
    begin
      if son[fa[y],1]=y then son[fa[y],1]:=x
      else son[fa[y],2]:=x;
    end
    else root:=x;
    fa[x]:=fa[y];
    son[y,3-w]:=son[x,w];
    if son[x,w]<>-1 then fa[son[x,w]]:=y;
    son[x,w]:=y;
    fa[y]:=x;
    update(y);
  end;

procedure splay(x,f:longint);
  var y:longint;
  begin
    while fa[x]<>f do
    begin
      y:=fa[x];
      if fa[y]=f then
      begin
        if son[y,1]=x then rotate(x,2)
        else rotate(x,1);
      end
      else begin
        if son[fa[y],1]=y then
        begin
          if son[y,1]=x then rotate(y,2) else rotate(x,1);
          rotate(x,2);
        end
        else begin
          if son[y,1]=x then rotate(x,2) else rotate(y,1);
          rotate(x,1);
        end;
      end;
    end;
    update(x); //这是学LCT的时候发现的一个优化，每次rotate只要update父节点即可，这样一下子快了2s多
  end;

procedure insert(x,y:longint);
  begin
    x:=find(x+1);
    splay(x,-1);
    inc(n);
    a[n]:=y;
    son[n,2]:=son[x,2];
    fa[son[x,2]]:=n;
    son[x,2]:=n;
    fa[n]:=x;
    update(n);
    update(x);
  end;

procedure change(x,y:longint);
  begin
    x:=find(x+1);
    splay(x,-1);
    a[x]:=y;
    update(x);
  end;

function build(l,r:longint):longint;
  var m:longint;
  begin
    m:=(l+r) shr 1;
    build:=m;
    if l<=m-1 then
    begin
      son[m,1]:=build(l,m-1);
      fa[son[m,1]]:=m;
    end;
    if m+1<=r then
    begin
      son[m,2]:=build(m+1,r);
      fa[son[m,2]]:=m;
    end;
    update(m);
  end;

function check(x,l,r:longint):longint;
  var y:longint;
  begin
    y:=find(l+r+1);
    splay(x,-1);
    splay(y,x);
    exit(hash[son[y,1]]);
  end;

function ask(x,y:longint):longint;
  var l,r,m,wx,wy:longint;
  begin
    l:=0;
    r:=n-y;
    if n-x<r then r:=n-x;
    ask:=0;
    wx:=find(x);
    wy:=find(y);
    while l<=r do
    begin
      m:=(l+r) shr 1;
      if check(wx,x,m)=check(wy,y,m) then
      begin
        l:=m+1;
        ask:=m;
      end
      else r:=m-1;
    end;
  end;

begin
  fillchar(son,sizeof(son),255);
  fillchar(fa,sizeof(fa),255);
  read(ch);
  while (ch>='a') and (ch<='z') do
  begin
    inc(n);
    a[n]:=ord(ch)-96;
    read(ch);
  end;
  readln(m);
  d[0]:=1;
  for i:=1 to 100001 do
    d[i]:=d[i-1]*29 mod mo;
  root:=build(0,n+1);
  inc(n);
  for i:=1 to m do
  begin
    read(ch);
    if ch='Q' then
    begin
      readln(x,y);
      writeln(ask(x,y));
    end
    else if ch='I' then
    begin
      read(x);
      read(ch);
      readln(ch);
      y:=ord(ch)-96;
      insert(x,y);
    end
    else if ch='R' then
    begin
      read(x);
      read(ch);
      readln(ch);
      y:=ord(ch)-96;
      change(x,y);
    end;
  end;
end.