bzoj3166

首先不难想到穷举次大数
然后我们只要找到满足这个数是次大数的最大区间即可
显然答案只可能是这两种[LL[i]+1,R[i]-1]和[L[i]+1,RR[i]-1]
L[i]表示这个数ai左侧第一个比它大的数的位置，
LL[i]表示这个数ai左侧第二个比它的的数的位置
R[i],RR[i]同理
然后假如我们能快速求出这两个区间，那剩下来我们就可以交给可持久化trie解决
下面的问题是如何快速求这两个区间
首先L[i],R[i]比较简单，直接维护一个单调降的队列即可
问题就是LL[i],RR[i]，这里就只讲LL[i]了
关注到LL[i]一定在L[i]左侧，从L[i]左侧第一个数考虑，如果它比a[i]大，那它就是左边大于a[i]的第二个数
如果小于，那么L[L[i]-1]+1~L[i]-1一定也不会比a[i]大，我们可以直接跳跃到L[L[i]-1]，以此类推
这样处理完所有的LL[i]，类似于最大子矩形的做法，均摊是O(n)
由此可以解决

var son:array[-1..10000010,0..1] of longint;
    h,ll,l,r,rr,q,a:array[-1..50010] of longint;
    n,t,x,i,s,ans:longint;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

function add(x,p:longint):longint;
  var i,q,y:longint;
  begin
    inc(t);
    add:=t;
    q:=t;
    for i:=30 downto 0 do
    begin
      y:=x and (1 shl i);
      if y>0 then y:=1;
      inc(t);
      son[q,y]:=t;
      son[q,1-y]:=son[p,1-y];
      p:=son[p,y];
      q:=t;
    end;
  end;

function ask(l,r,x:longint):longint;
  var i,q,y:longint;
  begin
    ask:=0;
    for i:=30 downto 0 do
    begin
      y:=x and (1 shl i);
      if y>0 then y:=1;
      if (son[r,1-y]=-1) or (son[r,1-y]=son[l,1-y]) then
      begin
        r:=son[r,y];
        l:=son[l,y];
      end
      else begin
        ask:=ask+1 shl i;
        r:=son[r,1-y];
        l:=son[l,1-y];
      end;
    end;
  end;

function sl(k:longint):longint;
  begin
    if (a[i]<a[k]) or (k=0) then exit(k)
    else exit(sl(l[k]));
  end;

function sr(k:longint):longint;
  begin
    if (a[i]<a[k]) or (k=n+1) then exit(k)
    else exit(sr(r[k]));
  end;

begin
  readln(n);
  fillchar(son,sizeof(son),255);
  h[0]:=1;
  t:=1;
  x:=1;
  for i:=30 downto 0 do
  begin
    inc(t);
    son[x,0]:=t;
  end;
  for i:=1 to n do
  begin
    read(a[i]);
    h[i]:=add(a[i],h[i-1]);
  end;
  a[n+1]:=2147483647;
  a[0]:=2147483647;
  q[1]:=1;
  s:=1;
  for i:=2 to n do
  begin
    while (s>0) and (a[i]>a[q[s]]) do dec(s);
    l[i]:=q[s];
    inc(s);
    q[s]:=i;
  end;
  q[0]:=n+1;
  q[1]:=n;
  s:=1;
  r[n]:=n+1;
  for i:=n-1 downto 1 do
  begin
    while (s>0) and (a[i]>a[q[s]]) do dec(s);
    r[i]:=q[s];
    inc(s);
    q[s]:=i;
  end;
  ll[1]:=0;
  for i:=2 to n do
    if l[i]>0 then ll[i]:=sl(l[i]-1)
    else ll[i]:=0;
  rr[n]:=n+1;
  i:=1;
  for i:=n-1 downto 1 do
    if r[i]<=n then rr[i]:=sr(r[i]+1)
    else rr[i]:=n+1;
  ans:=0;
  for i:=1 to n do
  begin
    if (l[i]=0) and (r[i]=n+1) then continue;
    if (l[i]=0) then
      ans:=max(ans,ask(h[0],h[rr[i]-1],a[i]))
    else if r[i]=n+1 then
      ans:=max(ans,ask(h[ll[i]],h[n],a[i]))
    else begin
      ans:=max(ans,ask(h[ll[i]],h[r[i]-1],a[i]));
      ans:=max(ans,ask(h[l[i]],h[rr[i]-1],a[i]));
    end;
  end;
  writeln(ans);
end.