bzoj2131

首先不难想到对t排序，有f[i]=max(f[j])+v[i] tj<=ti且abs(pi-pj)/2<=ti-tj;
要想优化，肯定从优化转移入手
先去绝对值，当pi>=pj时，可得2ti-pi>=2tj-pj
当pi<pj，可得2ti+pi>=2tj+pj; 这样两个式子的两边完全只和当前状态有关系
由于上面是等价变换，所以当同时满足2ti+pi>=2tj+pj和2ti-pi>=2tj-pj可得到tj<=ti且abs(pi-pj)/2<=ti-tj;
这就变成了求一个点左下方的点（包括边界）的点权最大值
这显然可以对一个坐标排序而对另一个坐标离散化然后用树状数组维护前缀最大值

var a,b,c,rank,d,v:array[0..100010] of longint;
    f,i,x,y,ans,n,m:longint;

function lowbit(x:longint):longint;
  begin
    exit(x and (-x));
  end;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure sorta(l,r: longint);
  var i,j,x,y: longint;
  begin
    i:=l;
    j:=r;
    x:=a[(l+r) shr 1];
    y:=b[(l+r) shr 1];
    repeat
      while (a[i]<x) or ((a[i]=x) and (b[i]<y)) do inc(i);
      while (x<a[j]) or ((a[j]=x) and (y<b[j])) do dec(j);
      if not(i>j) then
      begin
        swap(a[i],a[j]);
        swap(b[i],b[j]);
        swap(v[i],v[j]);
        inc(i);
        j:=j-1;
      end;
    until i>j;
    if l<j then sorta(l,j);
    if i<r then sorta(i,r);
  end;


procedure sortc(l,r: longint);
  var i,j,x,y: longint;
  begin
    i:=l;
    j:=r;
    x:=c[(l+r) div 2];
    repeat
      while c[i]<x do inc(i);
      while x<c[j] do dec(j);
      if not(i>j) then
      begin
        swap(c[i],c[j]);
        swap(d[i],d[j]);
        inc(i);
        j:=j-1;
      end;
    until i>j;
    if l<j then sortc(l,j);
    if i<r then sortc(i,r);
  end;

procedure work(x,y:longint);
  begin
    while x<=m do
    begin
      c[x]:=max(c[x],y);
      x:=x+lowbit(x);
    end;
  end;

function ask(x:longint):longint;
  begin
    ask:=0;
    while x>0 do
    begin
      ask:=max(ask,c[x]);
      x:=x-lowbit(x);
    end;
  end;

begin
  readln(m,n);
  for i:=1 to n do
  begin
    readln(x,y,v[i]);
    a[i]:=2*x-y;
    b[i]:=2*x+y;
  end;
  sorta(1,n);
  for i:=1 to n do
  begin
    c[i]:=b[i];
    d[i]:=i;
  end;
  sortc(1,n);
  m:=1;
  rank[d[1]]:=1;
  for i:=2 to n do
  begin
    if c[i]<>c[i-1] then inc(m);
    rank[d[i]]:=m;
  end;
  fillchar(c,sizeof(c),0);
  for i:=1 to n do
  begin
    f:=ask(rank[i])+v[i];
    ans:=max(ans,f);
    work(rank[i],f);
  end;
  writeln(ans);
end.