bzoj1458

题做多的话不难想到可能是以行列作为二分图两个点集，然后网络流相关

具体怎么弄呢

我们可以用求补集的思想，假设有解

我们先把棋盘能放的地方放满士兵，然后我们尽量的把士兵拿走

并且要满足行和列的要求，

说到这方法就很明显了

ans=n*m-障碍数-最大流

我们用x[i]表示棋盘放满后第i行最多能移开的士兵数

y[i]表示棋盘放满后第i列最多能移开的士兵数

然后建图就更明显了，不多说

无解预先判断一下即可

const inf=10000007;
type node=record
       next,point,flow:longint;
     end;

var edge:array[0..50010] of node;
    he,li,cur,p,numh,pre,h,d:array[0..300] of longint;
    a:array[0..110,0..110] of boolean;
    k,i,j,n,m,x,y,len,t:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,f:longint);
  begin
    inc(len);
    edge[len].point:=y;
    edge[len].flow:=f;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

function sap:longint;
  var u,i,j,neck,tmp,q:longint;
  begin
    neck:=inf;
    u:=0;
    numh[0]:=t+1;
    h[0]:=0;
    sap:=0;
    for i:=0 to t do
      cur[i]:=p[i];
    while h[0]<t+1 do
    begin
      d[u]:=neck;
      i:=cur[u];
      while i<>-1 do
      begin
        j:=edge[i].point;
        if (edge[i].flow>0) and (h[u]=h[j]+1) then
        begin
          neck:=min(neck,edge[i].flow);
          pre[j]:=u;
          cur[u]:=i;
          u:=j;
          if u=t then
          begin
            sap:=sap+neck;
            while u<>0 do
            begin
              u:=pre[u];
              j:=cur[u];
              dec(edge[j].flow,neck);
              inc(edge[j xor 1].flow,neck);
            end;
            neck:=inf;
          end;
          break;
        end;
        i:=edge[i].next;
      end;
      if i=-1 then
      begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then exit;
        tmp:=t;
        i:=p[u];
        q:=-1;
        while i<>-1 do
        begin
          j:=edge[i].point;
          if edge[i].flow>0 then
            if h[j]<tmp then
            begin
              tmp:=h[j];
              q:=i;
            end;
          i:=edge[i].next;
        end;
        h[u]:=tmp+1;
        cur[u]:=q;
        inc(numh[h[u]]);
        if u<>0 then
        begin
          u:=pre[u];
          neck:=d[u];
        end;
      end;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n,m,k);
  t:=n+m+1;
  for i:=1 to n do
    read(he[i]);
  for i:=1 to m do
    read(li[i]);
  for i:=1 to k do
  begin
    readln(x,y);
    a[x,y]:=true;
    inc(he[x]);
    inc(li[y]);
  end;
  for i:=1 to n do
  begin
    if he[i]>m then
    begin
      writeln('JIONG!');
      halt;
    end;
    add(0,i,m-he[i]);
    add(i,0,0);
  end;
  for i:=1 to m do
  begin
    if li[i]>n then
    begin
      writeln('JIONG!');
      halt;
    end;
    add(i+n,t,n-li[i]);
    add(t,i+n,0);
  end;
  for i:=1 to n do
    for j:=1 to m do
      if not a[i,j] then
      begin
        add(i,j+n,1);
        add(j+n,i,0);
      end;
  writeln(n*m-k-sap);
end.