poj3254

还是那句老话：dp关键在状态；

求有多少种排布方式，是任意两头牛不相邻（有些地方不能放）；

不用心，一开始还纠结了半天

和之前USACO上某题方法是一样的，每一行放或不放只有两种情况

把它当作一个二进制数，转化为十进制作为状态则

到第i行第j种状态的方案数为

f[i,j]=sigma f[i-1,k] (j and k=0) 很飘逸的位运算解决了不相邻（可以想一想为什么）；

code（代码比较丑陋 ）

const mo=100000000;
var a,f:array[0..20,0..5010] of longint;
    p,d:array[0..5010] of longint;
    v:array[0..20] of boolean;
    s,n,m,i,j,k,x,y,t:longint;
    ans:int64;
    ff:boolean;

function check(x:longint):boolean;
  begin
    s:=0;
    fillchar(p,sizeof(p),0);
    while x<>0 do
    begin
      inc(s);
      p[s]:=x mod 2;
      if (p[s]=1) then
      begin
        if v[s] then exit(false);
        if (p[s]=p[s-1]) then exit(false);
      end;
      x:=x shr 1;
    end;
    exit(true);
  end;

begin
  readln(n,m);
  t:=1 shl m-1;
  for i:=1 to n do
  begin
    fillchar(v,sizeof(v),false);
    for j:=1 to m do
    begin
      read(x);
      if x=0 then v[j]:=true;
    end;
    for j:=0 to t do
      if check(j) then
      begin
        inc(d[i]);
        a[i,d[i]]:=j;
      end;
    readln;
  end;
  for i:=1 to d[1] do
    f[1,i]:=1;
  for i:=2 to n do
  begin
    for j:=1 to d[i] do
    begin
      x:=a[i,j];
      for k:=1 to d[i-1] do
      begin
        y:=a[i-1,k];
        if x and y=0 then
          f[i,j]:=(f[i,j]+f[i-1,k]) mod mo;
      end;
    end;
  end;
  ans:=0;
  for i:=1 to d[n] do
    ans:=(ans+f[n,i]) mod mo;
  writeln(ans mod mo);
end.