bzoj3996

把这个式子弄清楚就知道这是最小割了

相当于，选某个点i有收入ai,i，会损失ci,

如果i,j都被选则有额外收入ai,j+aj,i

明显，对每个点i，连(s,i,∑ai,j) (i,t,ci)

对每对i,j连边(i,j,ai,j)，没了

const inf=100000007;
type node=record
       po,next,flow:longint;
     end;

var e:array[0..2000010] of node;
    p,numh,h,cur,pre,d:array[0..510] of longint;
    t,len,ans,i,j,n,m,x,s:longint;

procedure add(x,y,f:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].flow:=f;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure build(x,y,f:longint);
  begin
    add(x,y,f);
    add(y,x,0);
  end;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function sap:longint;
  var u,i,j,tmp,neck,q:longint;
  begin
    numh[0]:=t+1;
    for i:=0 to t do
      cur[i]:=p[i];
    u:=0; sap:=0; neck:=inf;
    while h[0]<t+1 do
    begin
      d[u]:=neck;
      i:=cur[u];
      while i<>-1 do
      begin
        j:=e[i].po;
        if (e[i].flow>0) and (h[u]=h[j]+1) then
        begin
          neck:=min(neck,e[i].flow);
          pre[j]:=u;
          cur[u]:=i;
          u:=j;
          if u=t then
          begin
            sap:=sap+neck;
            while u<>0 do
            begin
              u:=pre[u];
              j:=cur[u];
              dec(e[j].flow,neck);
              inc(e[j xor 1].flow,neck);
            end;
            neck:=inf;
          end;
          break;
        end;
        i:=e[i].next;
      end;
      if i=-1 then
      begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then break;
        q:=-1;
        tmp:=t;
        i:=p[u];
        while i<>-1 do
        begin
          j:=e[i].po;
          if e[i].flow>0 then
            if tmp>h[j] then
            begin
              q:=i;
              tmp:=h[j];
            end;
          i:=e[i].next;
        end;
        h[u]:=tmp+1;
        inc(numh[h[u]]);
        cur[u]:=q;
        if u<>0 then
        begin
          u:=pre[u];
          neck:=d[u];
        end;
      end;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n);
  t:=n+1;
  for i:=1 to n do
  begin
    s:=0;
    for j:=1 to n do
    begin
      read(x);
      s:=s+x;
      build(i,j,x);
    end;
    build(0,i,s);
    ans:=ans+s;
  end;
  for i:=1 to n do
  begin
    read(x);
    build(i,t,x);
  end;
  writeln(ans-sap);
end.