数据可视化之分析篇（六）使用Power BI进行流失客户分析

https://zhuanlan.zhihu.com/p/73358029

为了提升销量，在不断吸引新客户的同时，还要防止老客户离你而去，但每一个顾客不可能永远是你的客户，不可避免的都会经历新客户、活跃客户、流失客户的过程，这个过程也称为客户生命周期。

对客户生命周期管理至关重要，之前曾介绍过如何使用PowerBI分析新客户（如何使用Power BI计算新客户数量？），但一直没有写过流失客户的分析，正好最近有几个星友都提出了这个问题，所以专门写篇文章简要介绍一下思路。

 

---

 

每个公司由于业务特征、客户类型的区别、对流失客户的定义很可能不同。本文为了分析的方便，假设流失客户的定义是，最近6个月曾经下过单，但是最近三个月没有再次下单的客户。

 

举例来说，现在是2019年5月，如果某个客户在2018年12到2019年2月曾经下过单，但是从2019年3月到2019年5月都没有再购买过，那么该客户在5月就应标记为流失客户。

模拟数据为一张订单表和一个日期表，通过日期建立关系，这里是按照月份进行分析的，所以日期表中增加了一个跨年连续月份编号。

 

流失客户数量

 

我直接写一个度量值，

流失客户数量 = 
VAR customer_last3m=  
CALCULATETABLE(
    VALUES('订单'[客户姓名]),
    FILTER(
        ALL('日期表'),
        '日期表'[月份编号]<=SELECTEDVALUE('日期表'[月份编号])-3
        &&'日期表'[月份编号]>SELECTEDVALUE('日期表'[月份编号])-6))
VAR customer_cus3m=
CALCULATETABLE(
    VALUES('订单'[客户姓名]),
    FILTER(
        ALL('日期表'),
        '日期表'[月份编号]<=SELECTEDVALUE('日期表'[月份编号])
        &&'日期表'[月份编号]>SELECTEDVALUE('日期表'[月份编号])-3))
VAR customer_lost=EXCEPT(customer_last3m,customer_cus3m)
RETURN 
IF([订单最新日期]>=FIRSTDATE('日期表'[日期]),COUNTROWS(customer_lost))

 

VAR定义第一个变量customer_last3m，是返回前3个月下单的客户列表；

VAR定义第二个变量customer_cur3m，是返回最近3个月下单的客户列表；

VAR定义第三个变量customer_lost，利用EXCEPT函数，从customer_last3m的客户中中剔除customer_cur3m的客户，剩下的就是流失客户。

 

最后返回结果时，加了判断当前最新的订单日期的条件，是为了防止计算未来期间的流失客户。

结果如下，

 

 

度量值显示流失客户列表

 

由于度量值只能返回一个值，而流失客户是一个列表，有很多客户名称，上面的度量值通过计数进行聚合，返回了一个值。那么如何通过度量值来显示一个表呢？

可以通过CONCATENATEX函数，把列表的数据连接起来，变成一个字符串，这样就可以利用度量值来返回了，

 

流失客户 = 
VAR customer_last3m=  
CALCULATETABLE(
    VALUES('订单'[客户姓名]),
    FILTER(
        ALL('日期表'),
        '日期表'[月份编号]<=SELECTEDVALUE('日期表'[月份编号])-3
        &&'日期表'[月份编号]>SELECTEDVALUE('日期表'[月份编号])-6))
VAR customer_cus3m=
CALCULATETABLE(
    VALUES('订单'[客户姓名]),
    FILTER(
        ALL('日期表'),
        '日期表'[月份编号]<=SELECTEDVALUE('日期表'[月份编号])
        &&'日期表'[月份编号]>SELECTEDVALUE('日期表'[月份编号])-3))
VAR customer_lost=EXCEPT(customer_last3m,customer_cus3m)
RETURN 
IF([订单最新日期]>=FIRSTDATE('日期表'[日期]),CONCATENATEX(customer_lost,[客户姓名],"、"))

 

原理和第一个度量值一样，只是最后RETURN的结果不一样。

使用卡片图来显示这个度量值，

 

这样就变通的实现了用度量值来显示一个列表。

不过如果列表数据较少，用这种方式还可以，如果数据很多，比如上面的数据，一个卡片图显示不全，那就尽量不要用这种方式来展示流失客户了，直接通过新建表的方式，把流失客户单独生成一个表。

新建流失客户列表

 

通过新建表的方式来返回流失客户列表，比较直观，但是新表的方式就没有了外部上下文，不能通过点击切片器的形式来灵活的显示某个时间段的流失客户。

这里的表显示当前月的流失客户，新建表，输入：

流失客户表 = 
VAR cur_month=CALCULATE(MAX('日期表'[月份编号]),'日期表'[日期]=TODAY())
VAR customer_last3m=  
CALCULATETABLE(
    VALUES('订单'[客户姓名]),
    FILTER(
        ALL('日期表'),
        '日期表'[月份编号]<=cur_month-3
        &&'日期表'[月份编号]>cur_month-6))
VAR customer_cus3m=
CALCULATETABLE(
    VALUES('订单'[客户姓名]),
    FILTER(
        ALL('日期表'),
        '日期表'[月份编号]<=cur_month
        &&'日期表'[月份编号]>cur_month-3))
VAR customer_lost=EXCEPT(customer_last3m,customer_cus3m)
RETURN customer_lost

 

首先把当月的月份编号找出来，然后依然是前面度量值的思路，返回一个表就可以了。

并且这个表也会随着日期动态更新的。

通过这个简单的例子，应该能满足你利用DAX分析流失客户的问题，其中主要是通过日期粒度和时间段的选择，来定义流失客户的特征，相应修改DAX代码中关于粒度和时间段的条件就行了。

这里对流失客户的定义并不很严谨，可能会存在某客户重复标记为流失客户的问题，所以在具体分析时，首先应给流失客户下个明确的定义。定义清楚以后，利用本文的DAX思路来设计流失客户的条件就可以了。

如果你刚开始接触Power BI，可在微信公众号后台回复"PowerBI"，获取《七天入门PowerBI》电子书，帮你快速提升工作效率。

如果文章对你有帮助，别忘了点赞哦。