zoukankan      html  css  js  c++  java
  • 一步步写STM32 OS【一】 序言

      一直想写个类似uCOS的OS,近段时间考研复习之余忙里偷闲,总算有点成果了。言归正传,我觉得OS最难的部分首先便是上下文切换的问题,他和MCU的架构有关,所以对于不同的MCU,这部分需要移植。一旦这个问题解决了,整个OS算是成功了一半了,当然,是对于简单的OS。

      好了,要写一个OS,首先需要一个开发板和仿真器。我的开发板是STM32F4DISCOVERY,自带ST-LINK V2仿真器,板载MCU为STM32F407VGT6,支持FPU,32位ARM Cortex-M4F核,1024KB FLASH,192 KB RAM,总之很强大。对STM32其他系列,本OS几乎不需修改修改就可使用。开发环境为IAR for ARM 6.5,如果是MDK的话,也是大同小异,汇编部分需要修改。

      研究了一下UCOS-II的Cortex-M4的Port部分,觉得很好,就直接拿来用了,修改的很少。首先我们来看一下这一部分几个比较重要的函数,打开os_cpu_a.asm文件,定位到下面的地方,注释我改成中文了。当OS初始化完毕后,执行OSStart,OSStart最后调用OSStartHighRdy函数,注意在此之前的线程模式和异常模式的堆栈都是MSP,在此之后线程模式的堆栈是PSP,异常模式的堆栈仍是MSP。

    OSStartHighRdy
        LDR     R0, =NVIC_SYSPRI14         ; 设置PendSV的异常中断优先级
        LDR     R1, =NVIC_PENDSV_PRI
        STRB    R1, [R0]
    
        MOVS    R0, #0                     ; 初始化PSP=0
        MSR     PSP, R0
    
        LDR     R0, =OS_CPU_ExceptStkBase  ; 初始化异常堆栈MSP地址
        LDR     R1, [R0]
        MSR     MSP, R1    
    
        LDR     R0, =OSRunning             ; 置OSRunning = TRUE
        MOVS    R1, #1
        STRB    R1, [R0]
    
        LDR     R0, =NVIC_INT_CTRL         ; 触发PendSV异常 (引起上下文切换)
        LDR     R1, =NVIC_PENDSVSET
        STR     R1, [R0]
    
        CPSIE   I                          ; 开启中断,于是进入PendSV异常
    
    OSStartHang
        B       OSStartHang                ; 正常情况下,不应运行到这

      其中最核心的函数应该是OS_CPU_PendSVHandler了,它处理PendSV中断,完成上下文切换。

    OS_CPU_PendSVHandler
        CPSID   I                              ; 关中断
        MRS     R0, PSP                        ; 获得PSP
        CBZ     R0, OS_CPU_PendSVHandler_nosave; PSP为0跳到OS_CPU_PendSVHandler_nosave,即不保存上文,直接进入下文。
                                               ; 问什么呢,因为首次调用,是没有上文的。
                                               ; 保存上文
        SUBS    R0, R0, #0x20                  ; 因为寄存器是32位的,4字节对齐,自动压栈的寄存器有8个,所以偏移为8*0x04=0x20
        STM     R0, {R4-R11}                   ; 除去自动压栈的寄存器外,需手动将R4-R11压栈
    
        LDR     R1, =OSTCBCur                  ; 保存上文的SP指针 OSTCBCur->OSTCBStkPtr = SP;
        LDR     R1, [R1]
        STR     R0, [R1]                                            
    
                                                                    
    OS_CPU_PendSVHandler_nosave                ; 切换下文
        PUSH    {R14}                          ; LR压栈,下面要调用C函数
        LDR     R0, =OSTaskSwHook              ; 调用OSTaskSwHook();
        BLX     R0
        POP     {R14}
    
        LDR     R0, =OSPrioCur                 ; 置OSPrioCur = OSPrioHighRdy;
        LDR     R1, =OSPrioHighRdy
        LDRB    R2, [R1]
        STRB    R2, [R0]
    
        LDR     R0, =OSTCBCur                  ; 置OSTCBCur  = OSTCBHighRdy;
        LDR     R1, =OSTCBHighRdy
        LDR     R2, [R1]
        STR     R2, [R0]
    
        LDR     R0, [R2]                       ; R0中的值为新任务的SP; SP = OSTCBHighRdy->OSTCBStkPtr;
        LDM     R0, {R4-R11}                   ; 手动弹出 R4-R11
        ADDS    R0, R0, #0x20
       
            
        MSR     PSP, R0                        ; PSP = 新任务SP
        ORR     LR, LR, #0x04                  ; 确保异常返回后使用PSP
        CPSIE   I
        BX      LR                             ; 退出异常,从PSP弹出xPSR,PC,LR,R0-R3,进入新任务运行    

      之后我们在此基础上构建自己的OS,首先完成两个任务互相调用,然后是加入SysTick的任务调度,最后加入信号量,邮箱等功能。

  • 相关阅读:
    [面试没答上的问题1]http请求,请求头和响应头都有什么信息?
    模拟进度条发现的彩蛋
    实现JavaScript forEach
    JavaScript实现动画效果
    Contents Of My Blogs
    阅读笔记-拍出好照片的30个构图基本功
    阅读笔记-李鸿章传
    阅读笔记-人性的弱点
    阅读笔记-XWord:未来进化
    阅读笔记-活法
  • 原文地址:https://www.cnblogs.com/sky1991/p/stepbystep_stm32_os_1.html
Copyright © 2011-2022 走看看