asp入门之操作数据库

asp操作数据库常用的方式就是使用内置的组件adobd来实现，代码简洁，使用方便。
下面是读取access数据库的示例代码，使用了Connection对象和Recordset对象。
<%
    dim conn,connstr
    Set conn = Server.CreateObject("ADODB.Connection")
    connstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("db.mdb")
    conn.Open connstr
    
    dim rs
    Set rs = Server.CreateObject("ADODB.Recordset")
    rs.Open "select * from info order by createtime desc",conn,1,3
    if not rs.EOF then
        for i=1 to rs.recordcount
            response.Write(rs("title") & "<br />")
            rs.movenext
            if rs.eof then exit for    
        next
    end if
    
    rs.close
    set rs = nothing
    conn.close
    set conn = nothing
%>

更改数据库，添加一条数据库记录，使用recordset对象
<%

    dim title
    dim content
    
    title="我是第二个标题"
    content="我是第二个内容"
    
    dim conn,connstr
    Set conn = Server.CreateObject("ADODB.Connection")
    connstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("db.mdb")
    conn.Open connstr
    
    set rs=server.createobject("adodb.recordset")
    sql="select * from info where 0=1" 
    rs.open sql,conn,1,3
        rs.addnew
        rs("title")=title
        rs("content")=content
        rs("createtime")=date()
        rs.update
    rs.close
    set rs=nothing
    conn.close
    set conn = nothing
%>

更改数据库，修改一条数据库记录，使用recordset对象
<%
    dim id
    dim title
    dim content
    
    id=2    '初始化id    
    title="修改我是第二个标题"
    content="修改我是第二个内容"
    
    
    dim conn,connstr
    Set conn = Server.CreateObject("ADODB.Connection")
    connstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("db.mdb")
    conn.Open connstr    
    
    set rs=server.createobject("adodb.recordset")
    sql="select * from info where ID="&id 
    rs.open sql,conn,3,3
        rs("title")=title
        rs("content")=content
        rs.update
    rs.close
    set rs=nothing
    conn.close
    set conn = nothing
%>
还可以只使用Connection对象,添加、修改、删除等操作都可以使用下面的方法。
<%
    dim id
    
    id=2    '初始化id
    
    dim conn,connstr
    Set conn = Server.CreateObject("ADODB.Connection")
    connstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("db.mdb")
    conn.Open connstr
    
    sql="delete from info where id="&id
    conn.Execute sql,stateflag
    
    if stateflag=1 then
        response.write "操作成功"
    else
        response.write "操作失败"
    end if
%>
access数据库连接字符串还可以变换为
<%
connStr="driver={Microsoft Access Driver (*.mdb)};dbq=" & Server.MapPath("db.mdb")
%>
access数据库如果有密码的，只要将connstr更改为如下就可以了
<%
connStr="driver={microsoft access driver(*.mdb)};uid=admin;pwd=数据库密码;dbq=" & Server.MapPath("db.mdb")
%>

操作sql server数据库只要将connstr更改一下就可以了
<%
connStr="Provider=SQLOLEDB.1;Password=sa;Persist Security Info=True;User ID=sa;Initial Catalog=mydb;Data Source=LBWIN7\SQLSERVER2005"
%>
其中Data Source是数据库所在的计算机和数据库库示例名称，计算机名称可以是ip地址，也可以是计算机名称，计算机上如果安装多个数据库时的实例是不一样的。
LBWIN7\SQLSERVER2005中，LBWIN7是计算机名称，SQLSERVER2005是数据库实例名称。
Initial Catalog，数据库名称。
User ID，数据库登录名称。
Password，数据库登录密码。