Bzoj 1003[zjoi2006]货流运输trans

题目：物流公司要把一批货物从码头A运到码头B。由于货物量比较大，需要n天才能运完。货物运输过程中一般要转停好几个码头。物流公司通常会设计一条固定的运输路线，以便对整个运输过程实施严格的管理和跟踪。由于各种因素的存在，有的时候某个码头会无法装卸货物。这时候就必须修改运输路线，让货物能够按时到达目的地。但是修改路线是一件十分麻烦的事情，会带来额外的成本。因此物流公司希望能够订一个n天的运输计划，使得总成本尽可能地小。第一行是四个整数n（1<=n<=100）、m（1<=m<=20）、K和e。n表示货物运输所需天数，m表示码头总数，K表示每次修改运输路线所需成本。接下来e行每行是一条航线描述，包括了三个整数，依次表示航线连接的两个码头编号以及航线长度（>0）。其中码头A编号为1，码头B编号为m。单位长度的运输费用为1。航线是双向的。 再接下来一行是一个整数d，后面的d行每行是三个整数P（ 1 < P < m）、a、b（1 < = a < = b < = n）。表示编号为P的码头从第a天到第b天无法装卸货物（含头尾）。同一个码头有可能在多个时间段内不可用。但任何时间都存在至少一条从码头A到码头B的运输路线。

解：我弱爆了T T,看了题解觉得巨水无比，都是自己不肯好好想，觉得“这一定是一条碉堡的搜索题！”我是有多爱搜索T T。

正解是dp+最短路，方程：

Dp[i] := min(dp[j] + cost(j+1, i)*(i-j) + k) (0<=j<i)  初始化dp[0] := -k;

Cost(a, b)表示在时间a天到b天内，一条可行的从源点到汇点的最短路

最优性也毋庸置疑，因为如果在第j天不换是最优解也用担心，因为在dp[j]的换点k扫描到就等价于第j天也不换了，而k<j<i， 这个策略也一定会扫描到，数据范围小，随便搞

//bzoj 1003 [zjoi2006] trans
const
        maxm=21;
        maxn=111;
        inf='1.txt';
        bilibili=maxlongint >> 1;
type
        data=record
          st, ed: longint;
        end;
var
        dp: array[0..maxn]of longint;
        g: array[0..maxm, 0..maxm]of longint;
        tot: array[0..maxm]of longint;
        rule: array[0..maxm, 0..maxm]of data;
        //spfa
        dist, q: array[0..maxm]of longint;
        visit: array[0..maxm]of boolean;
        sink, source, n, m, k, e, d: longint;
procedure init;
var
        i, x, y, p: longint;
begin
  filldword(dp, sizeof(dp)>>2, bilibili);
  fillchar(g, sizeof(g), 0);
  fillchar(tot, sizeof(tot), 0);
  readln(n, m, k, e);
  source := 1; sink := m;
  for i := 1 to e do begin
    readln(x, y, p);
    if (g[x, y]=0)or(p<g[x, y]) then begin
      g[x, y] := p;
      g[y, x] := p;
    end;
  end;
  readln(d);
  for i := 1 to d do begin
    readln(p, x, y);
    inc(tot[p]);
    with rule[p, tot[p]] do begin
      st := x; ed := y;
    end;
  end;
end;

function check(x, a, b: longint): boolean;
var
        i: longint;
begin
  check := true;
  for i := 1 to tot[x] do
    with rule[x, i] do
      if ((a<=st)and(st<=b))or((a<=ed)and(ed<=b)or((st<a)and(ed>b))) then exit(false);
end;

function cost(e, b: longint): longint;
var
        head, i, u, tail: longint;
begin
  filldword(dist, sizeof(dist)>>2, bilibili);
  fillchar(visit, sizeof(visit), 0);
  head := 0; tail := 1;
  q[tail] := source; dist[source] := 0; visit[source] := true;
  repeat
    inc(head); if head=maxm then head := 1;
    u := q[head];
    visit[u] := false;
    for i := 1 to m do
      if i<>u then
        if check(i, b, e) then
          if (g[u, i]>0)and(dist[u]+g[u, i] < dist[i]) then begin
            dist[i] := dist[u] + g[u, i];
            if not visit[i] then begin
              visit[i] := true;
              inc(tail); if tail=maxm then tail := 1;
              q[tail] := i;
            end;
          end;
  until head=tail;
  exit(dist[sink]);
end;

procedure main;
var
        i, j: longint;
        tmp: int64;
begin
  dp[0] := -k;
  for i := 1 to n do
    for j := 0 to i-1 do begin   //this maybe > maxlongint because bilibili * x(x>3) > maxlongint
      tmp := dp[j] + int64(cost(i, j+1))*(i-j) + k;
      if tmp<dp[i] then dp[i] := tmp;
    end;
end;

procedure print;
begin
  writeln(dp[n]);
end;

begin
  assign(input,inf); reset(input);
  init;
  main;
  print;
end.