POJ 1515

题目大意：给出一副无向联通图，求把一些边改成有向边之后，整幅图还是为一个强连通分量。

p.s．一开始在本地做的，没读懂题意，其实是让你把边改有向而非删除边，好像要求改的数量最多，本地我提交了一个把边读入输出的程序本地spj过了= =，poj上wa了才真正想算法的。

解：我原意是把桥找出来，然后其他遍历，不过好像调错的样子。听说了fjy刷了个16ms p组第一，所以去参考了下，发现就是tarjan途中，桥输出双向，其他单向即可（因为tarjan就是在找一个最大的环），所以tarjan图中处理输出就行(注意横叉边也要输一次，也就是说除了输环，桥输双向，其他任意)，不过后来还是跑了32ms..

//poj 1515
const
        maxn=1011;
        maxm=maxn*4;
        inf='street.in';
        ouf='street.out';
type
        type_edge=record
          st, dest, next, op: longint;
        end;
var
        edge: array[0..maxm*2]of type_edge;
        vect, dfn, low: array[0..maxn]of longint;
        visit: array[0..maxn]of boolean;
        key: array[0..maxm*2]of boolean;
        test, edge_tot, n, m, stack_tot, time: longint;
procedure add(x, y: longint);
begin
  inc(edge_tot);
  with edge[edge_tot] do begin
    st := x;
    dest := y;
    next := vect[x];
    vect[x] := edge_tot;
    op := edge_tot+1;
  end;
  inc(edge_tot);
  with edge[edge_tot] do begin
    st := y;
    dest := x;
    next := vect[y];
    vect[y] := edge_tot;
    op := edge_tot - 1;
  end;
end;

procedure init;
var
        i, x, y: longint;
begin
  edge_tot := 0;
  fillchar(vect, sizeof(vect), 0);
  for i := 1 to m do begin
    readln(x, y);
    add(x, y);
  end;
end;

procedure dfs(x, pre: longint);
var
        i, u, tmp: longint;
begin
  inc(time);
  dfn[x] := time; low[x] := time;
  inc(stack_tot);
  visit[x] := true;
  i := vect[x];
  while i<>0 do
   with edge[i] do begin
    if (dest=pre) then begin
      i := next;
      continue;
    end;
    if (dfn[dest]=0) then begin
      writeln(st, ' ', dest);
      dfs(dest, x);
      if low[dest]<low[x] then low[x] := low[dest];
      if dfn[x]<low[dest] then
        writeln(edge[op].st, ' ', edge[op].dest);
    end
    else if visit[dest] then begin
      if dfn[dest]<low[x] then begin
        low[x] := dfn[dest];
      end;
      if key[i] then begin
        writeln(st, ' ', dest);
        key[op] := false;
      end;
    end;
    i := next;
  end;
end;

procedure main;
begin
  fillchar(dfn, sizeof(dfn), 0);
  //fillchar(low, sizeof(low), 0);
  fillchar(visit, sizeof(visit), 0);
  //fillchar(pre, sizeof(pre), 0);
  fillchar(key, sizeof(key), true);
  time := 0;
  dfs(1, 0);
end;

begin
  assign(input,inf); reset(input);
  assign(output,ouf); rewrite(output);
  test := 0;
  readln(n, m);
  while n+m<>0 do begin
   inc(test);
    writeln(test);
    writeln;
    init;
    main;
    writeln('#');
    readln(n, m);
  end;
  close(input); close(output);
end.