[洛谷1156]垃圾陷阱

题目描述

卡门――农夫约翰极其珍视的一条Holsteins奶牛――已经落了到“垃圾井”中。“垃圾井”是农夫们扔垃圾的地方，它的深度为D(2<=D<=100)英尺。
卡门想把垃圾堆起来，等到堆得与井同样高时，她就能逃出井外了。另外，卡门可以通过吃一些垃圾来维持自己的生命。
每个垃圾都可以用来吃或堆放，并且堆放垃圾不用花费卡门的时间。
假设卡门预先知道了每个垃圾扔下的时间t(0< t<=1000)，以及每个垃圾堆放的高度h(1<=h<=25)和吃进该垃圾能维持生命的时间f(1<=f<=30)，要求出卡门最早能逃出井外的时间，假设卡门当前体内有足够持续10小时的能量，如果卡门10小时内没有进食，卡门就将饿死。

输入输出格式

输入格式：

第一行为2个整数，D 和 G (1 <= G <= 100)，G为被投入井的垃圾的数量。
第二到第G+1行每行包括3个整数：T (0 < T <= 1000)，表示垃圾被投进井中的时间；F (1 <= F <= 30)，表示该垃圾能维持卡门生命的时间；和 H (1 <= H <= 25)，该垃圾能垫高的高度。

输出格式：

如果卡门可以爬出陷阱，输出一个整表示最早什么时候可以爬出；否则输出卡门最长可以存活多长时间。

输入输出样例

输入样例#1：

20 4
5 4 9
9 3 2
12 6 10
13 1 1

输出样例#1：

13

说明

[样例说明]
卡门堆放她收到的第一个垃圾：height=9；
卡门吃掉她收到的第二个垃圾，使她的生命从10小时延伸到13小时；
卡门堆放第3个垃圾，height=19；
卡门堆放第4个垃圾，height=20。

思路

　　首先一个槽点，这个题输入不一定按时间排序，所以先把垃圾按照时间排序。

　　网络上很多二维三维布尔型整型存放动态规划的值的数组，鉴于本人较笨，理解不了大神做法，只好原封不动的写一个近似背包的模型了。

　　一维数组ff[i]表示高度为i时最长能活多久，对于每个垃圾都有吃与不吃两种选择。如果不吃就能出去那就输出这个垃圾掉下去的时间。

　　其余参考题目注解。

type ss=record
    t,f,h:longint;
    end;

var a:array[1..100] of ss;
    ff:array[0..1000] of longint;//ff[i]表示高度为i时最长能活多久
    d,g:longint;

function max(x,y:longint):longint;
begin
    if x>y then exit(x) else exit(y);
end;

procedure init;
var i:longint;
begin
    readln(d,g);
    for i:=1 to g do readln(a[i].t,a[i].f,a[i].h);
end;

procedure sort(l,r: longint);
      var
         i,j,x:longint;y:ss;
      begin
         i:=l;
         j:=r;
         x:=a[(l+r) div 2].t;
         repeat
           while a[i].t<x do
            inc(i);
           while x<a[j].t do
            dec(j);
           if not(i>j) then
             begin
                y:=a[i];
                a[i]:=a[j];
                a[j]:=y;
                inc(i);
                j:=j-1;
             end;
         until i>j;
         if l<j then
           sort(l,j);
         if i<r then
           sort(i,r);
      end;

procedure main;
var i,j,k,m:longint;
begin
    for i:=1 to g do
        for j:=d downto 0 do
            if ff[j]>=a[i].t then//如果它能够坚持到垃圾掉下来的话
                begin
                    if j+a[i].h>=d then
                        begin
                            writeln(a[i].t);
                            halt;
                        end;
                    //能出去
                    ff[j+a[i].h]:=max(ff[j+a[i].h],ff[j]);//不吃
                    ff[j]:=ff[j]+a[i].f;//吃
                end;
end;

begin
    init;
    fillchar(ff,sizeof(ff),0);
    sort(1,g); 
    ff[0]:=10;
    main;
    writeln(ff[0]);//无法爬出，输出高度为零时（此时不用爬)最大存活时间
end.