[NOIP2000]方格取数

NOIP 2000 提高组第四题

题目描述

设有N*N的方格图(N<=9)，我们将其中的某些方格中填入正整数，而其他的方格中则放
人数字0。如下图所示（见样例）：
A
0  0  0  0  0  0  0  0
0  0 13  0  0  6  0  0
0  0  0  0  7  0  0  0
0  0  0 14  0  0  0  0
0 21  0  0  0  4  0  0
0  0 15  0  0  0  0  0
0 14  0  0  0  0  0  0
0  0  0  0  0  0  0  0
                           B
    某人从图的左上角的A点出发，可以向下行走，也可以向右走，直到到达右下角的B 
点。在走过的路上，他可以取走方格中的数（取走后的方格中将变为数字0）。
    此人从A点到B点共走两次，试找出2条这样的路径，使得取得的数之和为最大。

输入输出格式

输入格式：

输入的第一行为一个整数N（表示N*N的方格图），接下来的每行有三个整数，前两个
表示位置，第三个数为该位置上所放的数。一行单独的0表示输入结束。

输出格式：

只需输出一个整数，表示2条路径上取得的最大的和。

输入输出样例

输入样例#1：

8
2 3 13
2 6  6
3 5  7
4 4 14
5 2 21
5 6  4
6 3 15
7 2 14
0 0  0

输出样例#1：

67

思路

　　双线程动归

　　设f[i][j][k][l]为从 (0, 0) 位置由两条不交叉的线路走到 (i, j)，(k, l) 位置时的最大好感度和，则它的上一步可能有四种情况：

1. 第一个点由上走来，第二个点也由上走来，此时的好感度和为f[i - 1][j][k - 1][l]
2. 第一个点由上走来，第二个点则由左走来，此时的好感度和为f[i - 1][j][k][l - 1] 
3. 第一个点由左走来，第二个点则由上走来，此时的好感度和为f[i][j - 1][k - 1][l]
4. 第一个点由左走来，第二个点也由左走来，此时的好感度和为f[i][j - 1][k][l - 1] 

　　取四种情况中的最大者加上两个点的权值即可。

　　特判：一直到终点之前，为了防止路径重叠，不能让两个点相同，所以最后如果两个点相同的话，减去一个点的权值即可。

PS：这可是第一个一气敲完静态编译没报错并且全部AC的NOIP题目，撒花！！！

var a:array[0..10,0..10] of longint;
    f:array[0..10,0..10,0..10,0..10] of longint;
    n,i,j,k,l,x,y,z,sum:longint;

function max(q,w,e,r:longint):longint;
begin
    max:=q;
    if w>max then max:=w;
    if e>max then max:=e;
    if r>max then max:=r;
    exit(max);
end;

begin
    fillchar(f,sizeof(f),0);
    fillchar(a,sizeof(a),0);
    readln(n);
    while 0=0 do 
        begin
            readln(x,y,z);
            if (x=0)and(y=0)and(z=0) then break;
            a[x,y]:=z;
        end;
    for i:=1 to n do
        for j:=1 to n do 
            for k:=1 to n do 
                for l:=1 to n do
                    begin
                        sum:=max(f[i,j-1,k,l-1],f[i-1,j,k-1,l],f[i-1,j,k,l-1],f[i,j-1,k-1,l]);
                        if (k<>i)or(l<>j) then f[i,j,k,l]:=sum+a[i,j]+a[k,l]
                        else f[i,j,k,l]:=sum+a[i,j];
                    end;
    writeln(f[n,n,n,n])
end.