FPGA驱动步进电机

步进电机

　　步进电机是将电脉冲信号转变为角位移或线位移的开环控制电机，是现代数字程序控制系统中的主要执行元件，应用极为广泛。在非超载的情况下，电机的转速、停止的位置只取决于脉冲信号的频率和脉冲数，而不受负载变化的影响，当步进驱动器接收到一个脉冲信号，它就驱动步进电机按设定的方向转动一个固定的角度，称为“步距角”，它的旋转是以固定的角度一步一步运行的。可以通过控制脉冲个数来控制角位移量，从而达到准确定位的目的；同时可以通过控制脉冲频率来控制电机转动的速度和加速度，从而达到调速的目的。

五线四相步进电

　　机是从两个线圈中间引出两根线，作为公共端，因此有5根线。

　　五线四相步进电机一般采用8拍进行驱动。

verilog代码实现

//--------------------------------------------------------------
//功能：这是五线四相电机驱动模块，输入PWM.DIR,EN就可以控制电机的转动
//PWM:脉冲数越多电机转的角度或者圈数越多，PWM的频率越高，电机转速越快
//RST_n:低电平下降沿复位
//EN:使能信号
//M_OUT:电机控制时序输出引脚
//---------------------------------------------------------------

module motor_sig(
    PWM,  //驱动脉冲输入，脉冲数决定转的圈数，脉冲频率决定转速
    RST_n,//低复位
    DIR,//方向
    EN,//使能信号，1：有效   0：关闭
    //五线四相电机的输出引脚
    M_OUT
);

input PWM,RST_n,DIR,EN;
output  [3:0]M_OUT;//【a,b,c,d】
reg [3:0]motor_ctl;



always@(negedge RST_n or posedge PWM)
begin
    if(!RST_n)begin
        motor_ctl <= 4'b0000;
    end
    else begin
        if(EN)begin//使能信号有效
            if(DIR)begin//CCW
                case(motor_ctl)
                    4'b0000: motor_ctl <= 4'b1000;
                    4'b1000: motor_ctl <= 4'b1100;
                    4'b1100: motor_ctl <= 4'b0100;
                    4'b0100: motor_ctl <= 4'b0110;
                    4'b0110: motor_ctl <= 4'b0010;
                    4'b0010: motor_ctl <= 4'b0011;
                    4'b0011: motor_ctl <= 4'b0001;
                    4'b0001: motor_ctl <= 4'b1001;
                    4'b1001: motor_ctl <= 4'b1000;
                    default:motor_ctl <= 4'b1000;
                endcase    
            end
            else begin //CW
                case(motor_ctl)
                    4'b0000: motor_ctl <= 4'b1001;
                    4'b1001: motor_ctl <= 4'b0001;
                    4'b0001: motor_ctl <= 4'b0011;
                    4'b0011: motor_ctl <= 4'b0010;
                    4'b0010: motor_ctl <= 4'b0110;
                    4'b0110: motor_ctl <= 4'b0100;
                    4'b0100: motor_ctl <= 4'b1100;
                    4'b1100: motor_ctl <= 4'b1000;
                    4'b1000: motor_ctl <= 4'b1001;
                    default:motor_ctl <= 4'b1000;
                endcase            
            end
        end    
    end
end

assign M_OUT[3:0] = motor_ctl[3:0];


endmodule

仿真结果

四线二相步进电机

　　这种步进电机相当于五线四相步进电机没有引出抽头。如果将五线四相步进电机引出的抽头不使用。且两个抽头没有连接在一起，可以将其作为二相电机使用。

　　四线二相步进电机的驱动有八拍和四拍的。

　　八拍驱动时序：

　　八个状态：1、在 A 与 A-正电压，B 与 B-不给电悬空；2、在 A 与 A-正电压，B与 B-也给正电压；3、A 与 A-不给电压悬空，B 与 B-正电压；4、A 与 A-给负电压，B与B-给正电压；5、A与A-给负电压，B 与B-不给悬空；6、A与A-给负电压，B与B-给负电压；7、A 与A-不给电悬空，B 与 B-给负电压；8、A 与给正电压，B 与 B-给负电压；按以上八个状态轮流供电，控制一下脉宽就可以了。

　　实现

//--------------------------------------------------------------
//功能：这是四线二相电机驱动模块，输入PWM.DIR,EN就可以控制电机的转动
//PWM:脉冲数越多电机转的角度或者圈数越多，PWM的频率越高，电机转速越快
//RST_n:低电平下降沿复位
//EN:使能信号
//M_OUT:电机控制时序输出引脚
//---------------------------------------------------------------

module motor_sig_42(
    PWM,  //驱动脉冲输入，脉冲数决定转的圈数，脉冲频率决定转速
    RST_n,//低复位
    DIR,//方向
    EN,//使能信号，1：有效   0：关闭
    //四线二相电机的输出引脚
    M_OUT
);

input PWM,RST_n,DIR,EN;
output  [3:0]M_OUT;//【A+,A-,B+,B-】
reg [3:0]motor_ctl;



always@(negedge RST_n or posedge PWM)
begin
    if(!RST_n)begin
        motor_ctl <= 4'b0000;
    end
    else begin
        if(EN)begin//使能信号有效
            if(DIR)begin//CCW
                case(motor_ctl)
                    4'b0000: motor_ctl <= 4'b1000;
                    4'b1000: motor_ctl <= 4'b1010;
                    4'b1010: motor_ctl <= 4'b0010;
                    4'b0010: motor_ctl <= 4'b0110;
                    4'b0110: motor_ctl <= 4'b0100;
                    4'b0100: motor_ctl <= 4'b0101;
                    4'b0101: motor_ctl <= 4'b0001;
                    4'b0001: motor_ctl <= 4'b1001;
                    4'b1001: motor_ctl <= 4'b1000;
                    default:motor_ctl <= 4'b1000;
                endcase    
            end
            else begin //CW
                case(motor_ctl)
                    4'b0000: motor_ctl <= 4'b1001;
                    4'b1001: motor_ctl <= 4'b0001;
                    4'b0001: motor_ctl <= 4'b0101;
                    4'b0101: motor_ctl <= 4'b0100;
                    4'b0100: motor_ctl <= 4'b0110;
                    4'b0110: motor_ctl <= 4'b0010;
                    4'b0010: motor_ctl <= 4'b1010;
                    4'b1010: motor_ctl <= 4'b1000;
                    4'b1000: motor_ctl <= 4'b1001;
                    default:motor_ctl <= 4'b1000;
                endcase            
            end
        end    
    end
end

assign M_OUT[3:0] = motor_ctl[3:0];


endmodule

　　四拍驱动时序

总结

　　该模块可通过控制PWM信号实现电机旋转角度和旋转速度的控制，方便使用，移植方便。