洛谷1090 合并果子 解题报告

洛谷1090 合并果子

本题地址： http://www.luogu.org/problem/show?pid=1090

题目描述

在一个果园里，多多已经将所有的果子打了下来，而且按果子的不同种类分成了不同的堆。多多决定把所有的果子合成一堆。 

    每一次合并，多多可以把两堆果子合并到一起，消耗的体力等于两堆果子的重量之和。可以看出，所有的果子经过n-1次合并之后，就只剩下一堆了。多多在合并果子时总共消耗的体力等于每次合并所耗体力之和。 

    因为还要花大力气把这些果子搬回家，所以多多在合并果子时要尽可能地节省体力。假定每个果子重量都为1，并且已知果子的种类数和每种果子的数目，你的任务是设计出合并的次序方案，使多多耗费的体力最少，并输出这个最小的体力耗费值。 

    例如有3种果子，数目依次为1，2，9。可以先将1、2堆合并，新堆数目为3，耗费体力为3。接着，将新堆与原先的第三堆合并，又得到新的堆，数目为12，耗费体力为12。所以多多总共耗费体力=3+12=15。可以证明15为最小的体力耗费值。

输入输出格式

输入格式：

输入文件fruit.in包括两行，第一行是一个整数n(1<＝n<=10000)，表示果子的种类数。第二行包含n个整数，用空格分隔，第i个整数ai(1<＝ai<=20000)是第i种果子的数目。

输出格式：

输出文件fruit.out包括一行，这一行只包含一个整数，也就是最小的体力耗费值。输入数据保证这个值小于2^31。

输入输出样例

输入样例#1：

3 
1 2 9 

输出样例#1：

15

说明

对于30％的数据，保证有n<=1000： 
对于50％的数据，保证有n<=5000； 
对于全部的数据，保证有n<=10000。

题解

贪心

本题的基本算法是先把所有的堆进行快排，然后选取当前最小的两个堆进行合并，把合并后新产生的堆按插入排序的方法插入到堆的序列里面，插入后使它仍然有序，时间复杂度为O(n^2)。

我们也可以把新产生的堆存入队列，序列的大小一定是递增的，每次只需将队首元素和有序序列的最小值比较就可以了，这种策略可以AC。

下面附上代码。

代码

var
   a:array[0..15000] of longint;
   i,j,n,k,tem,sum:longint;

 procedure init;
 begin
    readln(n);
    for i:=1 to n do
        read(a[i]);
end;

procedure qsort(left,right:integer);
var i,j,x,t:longint;
begin
   i:=left;  j:=right;
   x:=a[i];
   repeat
     while (a[j]<x)and(i<j) do dec(j);
     if i<j then
     begin
       t:=a[i]; a[i]:=a[j];a[j]:=t;inc(i);
     end;
     while (a[i]>x)and(j>i) do inc(i);
     if i<j then
     begin
       t:=a[i]; a[i]:=a[j];a[j]:=t;dec(j);
     end;
   until i=j;
   inc(i);dec(j);
   if i<right then qsort(i,right);
   if j>left then qsort(left,j);
end;

procedure work;  //合并果子并不断维护数组
begin
   sum:=0;
   while n>=2 do
   begin
        tem:=a[n]+a[n-1];
        sum:=sum+tem;
        j:=1;
        while a[j]>tem do j:=j+1; //插入排序
        for k:=n downto j do
           a[k+1]:=a[k];
        a[j]:=tem;
   n:=n-1;  //整理数组
   end;
end;

begin
    init;
    qsort(1,n);
    work;
    writeln(sum);
end.

（本文系笔者原创，未经允许不得转载）