以传值和传引用的方式传递参数 IN OUT NOCOPY

传递子程序参数的方式有两种--传值和传引用。当以引用的方式传递参数的时候，就将指向实际参数的一个指针传递到相应的形式参数。另一方面，当以传值的方式传递参数的时候，就将实际参数的值复制到相应的形式参数。以引用的方式传递参数通常会更快，因为它避免了复制。对集合类型的参数而言，这表现更加明显，因为集合类型的数据一般都非常多。

默认情况下，PL/SQL对IN参数都使用传引用的方式，而对IN OUT和OUT参数都使用传值的方式。

1、NOCOPY的使用方法

parameter_name [mode] NOCOPY datatype

其中parameter_name是参数的名称，mode是参数模式，而datatype是参数类型。如果有NOCOPY，PL/SQL编译器就会尝试通过传引用的方式传递参数，而不是通过传值方式传递参数。注意，NOCPY只是一个编译器提示，而不是编译器命令，因此，这种提示并不一定总会被接受。

create or replace procedure no_copy_proc (
        p_inparam   in      number ,   
        p_outparam  out  nocopy  varchar2 ,
        p_inoutparam    in out nocopy varchar2 
        )as
begin
    null ;
end ;

在IN参数上使用NOCOPY时，会引发一个编译错误，因为IN参数总是以传引用方式传递参数的，因此不允许使用编译器提示NOCOPY。

2、带NOCOPY的异常语义

使用NOCOPY即使出现异常，NOCOPY也会自动处理。

以传递引用的方式传递参数的时候，对形式参数所做的任何更改都会同时反应到实际参数上，因为这二者指向的是同一个位置。这也意味着，如果过程在形式参数的值发生了变化以后，又以一个未处理的异常结束，那么在过程体内修改参数的值将会丢失。

 （1）例子：

declare
    v_a number := 10 ;  --定义变量
    v_b number := 20 ;
    procedure chenge_proc (
        p_a in out number , --定义参数
        p_b in out nocopy number 
    )as
    begin
        p_a := 100 ;    --修改参数内容
        p_b := 100 ;    --修改参数最直接的影响就是影响原始数据。
        RAISE_APPLICATION_ERROR(-20001, '测试NOCOPY') ;   --抛出异常
    end ;
begin
    DBMS_OUTPUT.PUT_LINE('过程调用之前：v_a :' || V_A || ' ---- v_b : ' || V_B) ;
    begin
        chenge_proc(v_a , v_b) ;    --传递参数
    exception 
        when others then 
            DBMS_OUTPUT.PUT_LINE('SQLCODE : ' || SQLCODE || ' , SQLERRM :' || SQLERRM) ;
    end ;
    DBMS_OUTPUT.PUT_LINE('过程调用之后：v_a :' || V_A || ' ---- v_b : ' || V_B) ;
end ;

（1）执行结果

过程调用之前：v_a :10 ---- v_b : 20
SQLCODE : -20001 , SQLERRM :ORA-20001: 测试NOCOPY
过程调用之后：v_a :10 ---- v_b : 100

我们可以看到，发生了异常，使用了NOCOPY的P_B修改了实际参数的值，而p_a并没有。

（2）例子：

CREATE OR REPLACE PROCEDURE RaiseErrorNoCopy (      -- 创建过程
  p_Raise IN BOOLEAN,   
  p_ParameterA OUT NOCOPY NUMBER    
  ) AS  
BEGIN  
  p_ParameterA := 7;  -- 修改实际参数的值
  IF p_Raise THEN  
    RAISE DUP_VAL_ON_INDEX;  --p_Raise为TRUE抛出异常
  ELSE  
    RETURN;  
  END IF;  
END RaiseErrorNoCopy;  

（2）执行结果

DECLARE  
  v_Num NUMBER := 1;    -- 定义变量
BEGIN  
  DBMS_OUTPUT.PUT_LINE('过程调用之前：' || v_Num);     
  RaiseErrorNoCopy(FALSE, v_Num);   --调用过程
  DBMS_OUTPUT.PUT_LINE('过程调用之后: ' || v_Num);  
  DBMS_OUTPUT.PUT_LINE('');     
    
  v_Num := 2;   --修改变量值
  DBMS_OUTPUT.PUT_LINE('过程调用之前: ' || v_Num);    
  RaiseErrorNoCopy(TRUE, v_Num);   --调用过程将会有异常抛出
EXCEPTION  
  WHEN OTHERS THEN  --处理异常
    DBMS_OUTPUT.PUT_LINE('过程调用之后: ' || v_Num);      
END;  

我们可以看到，即使发生了异常，还是两次修改了实际参数的值。

3、使用NOCOPY的一些限制

在某些情况下，编译器会忽略NOCOPY的存在，参数仍然以传值的方式进行传递，而且也不会产生任何错误。记住，NOCOPY只是一种pragma，编译器没有责任完全遵守这个提示。在下面几种情形中，会忽略NOCOPY的存在：

• 实际参数是联合数组的一个成员。但是，如果实际参数是整个数组，就不受这种约束的限制。
• 使用长度、精度或NOT NULL约束限制的实际参数。
• 实际参数和形式参数都是记录，并且它们要么被隐式声明为一个循环变量，要么是使用%ROWTYPE进行声明的，而且相应字段上的约束又不同。
• 传递的实际参数需要进行隐式的数据类型转换。
• 子程序被包含在进行远程过程调用（remote procedures call，RPC）中。

【转】http://blog.csdn.net/rudygao/article/details/24348795