Arduino I2C + 三轴加速度计ADXL345

ADXL345是ADI公司生产的三轴数字加速度计芯片，与ST的LIS3DH功能接近。主要特性有：

• 工作电压：2.0 ~ 3.6V
• 功耗：待机功耗0.1μA；工作时与数据输出频率（ODR）有关，如ODR<10 Hz时30μA
• 接口：I2C；三线/四线制SPI
• 分辨率：可选择，最大13-bit
• 内置FIFO
• single tap/double tap检测
• 自由落体检测
• 两个可编程中断输出脚
• 封装：3 x 5 x 1 mm LGA
  
  

管脚定义

与Arduino的连接

用工作于3.3V/8MHz版本的Arduino Pro Mini进行调试。管脚定义、连接方法与调试LIS3DH时类似。采用I2C接口进行通讯，未利用FIFO和INT1、INT2中断引脚。

ADXL345       Pro Mini (3.3V)

VDD <------> 3.3V

GND <------> GND

SCL <------>  A5 (SCL)

SDA <------> A4 (SDA)

功能调试

1. 操作方法亦和LIS3DH类似。但ADXL345似乎没有与LIS3DH的STATUS_REG寄存器，而是设定DATA_READY中断，然后利用INT_SOURCE寄存器判断是否有中断事件发生，从而判断是否有新的测量值。

2. 留意设置的ODR频率不要超出I2C总线的数据读取速率。如Arduino的I2C总线时钟频率为100kHz，则可设置的最大ODR为200Hz。

测试代码

/*
    Measurement of acceleration values using motion sensor ADXL345 
*/
#include <Wire.h>

#define ADDRESS_ADXL345 0x53
#define DATA_FORMAT 0x31
#define BW_RATE 0x2C
#define POWER_CTL 0x2D
#define INT_ENABLE 0x2E
#define INT_SOURCE 0x30
#define DATAX0 0x32

byte buffer[6];
byte intSource;

boolean ready = false;

int outX, outY, outZ;
float xVal, yVal, zVal;

void setup()
{
    Wire.begin();
    Serial.begin(9600);

    delay(2);

    // set scale = +/- 2g, 13-bit mode
    Wire.beginTransmission(ADDRESS_ADXL345);
    Wire.write(DATA_FORMAT); 
    Wire.write(0x08);
    Wire.endTransmission();
    // set ODR = 1.56 Hz
    Wire.beginTransmission(ADDRESS_ADXL345);
    Wire.write(BW_RATE); 
    Wire.write(0x04);
    Wire.endTransmission();

    // start measurement
    Wire.beginTransmission(ADDRESS_ADXL345);
    Wire.write(POWER_CTL); 
    Wire.write(0x08);
    Wire.endTransmission();
    
    // enable DATA_READY interrupt
    Wire.beginTransmission(ADDRESS_ADXL345);
    Wire.write(INT_ENABLE); 
    Wire.write(0x80);
    Wire.endTransmission();
}

void loop()
{
    // check data ready
    while(ready == false)
    {
        Wire.beginTransmission(ADDRESS_ADXL345);
        Wire.write(INT_SOURCE); 
        Wire.endTransmission();
        Wire.requestFrom(ADDRESS_ADXL345, 1);
        if (Wire.available() >= 1)
        {
            intSource = Wire.read();
        }
        if (bitRead(intSource, 7) == 1) //new data available
        {
            ready = true;
        }
    }
    if (bitRead(intSource, 0) == 1)
    {
        Serial.println("Some data have been overwritten.");
    }
    
    //read the result
    Wire.beginTransmission(ADDRESS_ADXL345);
    Wire.write(DATAX0); //read multiple bytes
    Wire.endTransmission();
    Wire.requestFrom(ADDRESS_ADXL345, 6);
    if (Wire.available() >= 6)
    {
        for (int i = 0; i < 6; i++)
        {
            buffer[i] = Wire.read();
        }
    }

    //calculation
    outX = (buffer[1] << 8) | buffer[0]; 
    outY = (buffer[3] << 8) | buffer[2]; 
    outZ = (buffer[5] << 8) | buffer[4]; 
    xVal = outX *3.9;
    yVal = outY *3.9;
    zVal = outZ *3.9;

    Serial.print("outX: "); Serial.print(xVal); Serial.print("  ");
    Serial.print("outY: "); Serial.print(yVal); Serial.print("  ");
    Serial.print("outZ: "); Serial.println(zVal);

    ready = false;
}

ODR设定为1.56Hz，通过串口打印三个维度的加速度值，单位为mg。

参考资料

ADXL345 - Analog Devices