vijos1067守望者的逃离

裸的矩阵乘法，我却调了一上午……弱到爆啊……

不过最终辛苦没有白费，我终于彻底搞懂了

要注意几点：

一、必须构造出前几项

二、用矩阵乘法算法之后还要手工算答案，利用首先算好的前几项

三、想好自己构造的矩阵是横着的还是竖着的

四、要用一个单位矩阵存储最后的结果

代码：（不容易啊）

type matrix=array[1..15,1..15] of int64;
var i,n,k,j:longint;
     ans:int64;
     a,b:matrix;
     f:array[0..15] of int64;
function mo(x:int64):int64;
 begin
   mo:=x mod 7777777;
 end;
procedure mul(var x,y,z:matrix);
 var i,j,l:longint;
     t:matrix;
   begin
     fillchar(t,sizeof(t),0);
     for i:=1 to k do
      for j:=1 to k do
       for l:=1 to k do
        t[i,j]:=mo(t[i,j]+x[i,l]*y[l,j]);
     z:=t;
   end;
procedure ksm(times:longint);
   begin
   while times<>0 do
    begin
      if times and 1=1 then mul(a,b,b);
      times:=times>>1;
      mul(a,a,a);
    end;
   end;
procedure init;
 begin
   readln(k);readln(n);
   fillchar(a,sizeof(a),0);
   fillchar(b,sizeof(b),0);
   for i:=1 to k do a[1,i]:=1;
   for i:=2 to k do a[i,i-1]:=1;
   for i:=1 to k do b[i,i]:=1;
   f[0]:=1;f[1]:=1;
   for i:=2 to k do
     for j:=0 to i-1 do
      f[i]:=mo(f[i]+f[j]);
   if n<=k then begin writeln(f[n]);halt;end;
 end;
procedure main;
 begin
   ksm(n-k);
   ans:=0;
   for i:=1 to k do ans:=mo(ans+b[1,i]*f[k+1-i]);
   writeln(ans);
 end;
begin
  init;
  main;
end.