线性规划与网络流10 餐巾计划问题

算法实现题 8-10 餐巾计划问题（习题 8-21）
?问题描述：
一个餐厅在相继的 N 天里，每天需用的餐巾数不尽相同。假设第 i 天需要 ri块餐巾(i=1，
2，…，N)。餐厅可以购买新的餐巾，每块餐巾的费用为 p 分；或者把旧餐巾送到快洗部，
洗一块需 m 天，其费用为 f 分；或者送到慢洗部，洗一块需 n 天(n>m)，其费用为 s<f 分。
每天结束时，餐厅必须决定将多少块脏的餐巾送到快洗部，多少块餐巾送到慢洗部，以及多
少块保存起来延期送洗。但是每天洗好的餐巾和购买的新餐巾数之和，要满足当天的需求量。
试设计一个算法为餐厅合理地安排好 N 天中餐巾使用计划，使总的花费最小。
?编程任务：
编程找出一个最佳餐巾使用计划.
?数据输入：
由文件 input.txt 提供输入数据。文件第 1 行有 6 个正整数 N,p,m,f,n,s。N 是要安排餐巾
使用计划的天数；p 是每块新餐巾的费用；m 是快洗部洗一块餐巾需用天数；f 是快洗部洗
一块餐巾需要的费用；n 是慢洗部洗一块餐巾需用天数；s 是慢洗部洗一块餐巾需要的费用。
接下来的 N 行是餐厅在相继的 N 天里，每天需用的餐巾数。
?结果输出:
程序运行结束时，将餐厅在相继的 N 天里使用餐巾的最小总花费输出到文件 output.txt
中。
输入文件示例
输出文件示例
input.txt
output.txt
3 10 2 3 3 2
5
6
7
145

题解：

其实构图不难想，关键在于细节的处理-----边的容量设置

而且还要注意读题，题中说可以延期洗，所以应该从i到i+1连一条容量为inf的边，inf是因为有可能积淀了好几天

注意到这一点后，同理 i 向 i+t1+n 连边的容量也需要时inf，i+t2+n 的容量也是inf

其实这题和saveprint那题有点像，构图都是比较巧妙的

代码：

uses math;
const inf=maxlongint;
type node=record
     from,go,next,v,c:longint;
     end;
var e:array[0..2000000] of node;
    pre,head,q,d:array[0..1000000] of longint;
    v:array[0..1000000] of boolean;
    i,j,n,s,t,l,r,mincost,tot,p,t1,t2,p1,p2,x:longint;
procedure ins(x,y,z,w:longint);
 begin
 inc(tot);
 with e[tot] do
  begin
  from:=x;go:=y;v:=z;c:=w;next:=head[x];head[x]:=tot;
  end;
 end;
procedure insert(x,y,z,w:longint);
 begin
 ins(x,y,z,w);ins(y,x,0,-w);
 end;
function spfa:boolean;
 var i,x,y:longint;
 begin
 fillchar(v,sizeof(v),false);
 for i:=s to t do d[i]:=inf;
 l:=0;r:=1;q[1]:=s;d[s]:=0;v[s]:=true;
 while l<r do
  begin
  inc(l);
  x:=q[l];v[x]:=false;
  i:=head[x];
  while i<>0 do
   begin
   y:=e[i].go;
   if (e[i].v<>0) and (d[x]+e[i].c<d[y]) then
    begin
    d[y]:=d[x]+e[i].c;
    pre[y]:=i;
    if not(v[y]) then
     begin
     v[y]:=true;
     inc(r);
     q[r]:=y;
     end;
    end;
   i:=e[i].next;
  end;
 end;
 exit(d[t]<>inf);
 end;
procedure mcf;
 var i,tmp:longint;
 begin
 mincost:=0;
 while spfa do
  begin
  tmp:=inf;
  i:=pre[t];
  while i<>0 do
   begin
   tmp:=min(tmp,e[i].v);
   i:=pre[e[i].from];
   end;
  inc(mincost,tmp*d[t]);
  i:=pre[t];
  while i<>0 do
   begin
   dec(e[i].v,tmp);
   inc(e[i xor 1].v,tmp);
   i:=pre[e[i].from];
   end;
  end;
 end;
procedure init;
 begin
 tot:=1;
 readln(n,p,t1,p1,t2,p2);
 s:=0;t:=2*n+1;
 for i:=1 to n do
  begin
  readln(x);
  insert(s,i,x,0);
  insert(s,i+n,x,p);
  insert(i+n,t,x,0);
  if i+1<=n then insert(i,i+1,inf,0);
  if i+t1<=n then insert(i,i+t1+n,inf,p1);
  if i+t2<=n then insert(i,i+t2+n,inf,p2);
  end;
 end;
procedure main;
 begin
 mincost:=0;
 mcf;
 writeln(mincost);
 end;
begin
 assign(input,'input.txt');assign(output,'output.txt');
 reset(input);rewrite(output);
 init;
 main;
 close(input);close(output);
end.