洛谷——P1514 引水入城

题目描述

在一个遥远的国度，一侧是风景秀美的湖泊，另一侧则是漫无边际的沙漠。该国的行政区划十分特殊，刚好构成一个N 行M 列的矩形，如上图所示，其中每个格子都代表一座城市，每座城市都有一个海拔高度。

为了使居民们都尽可能饮用到清澈的湖水，现在要在某些城市建造水利设施。水利设施有两种，分别为蓄水厂和输水站。蓄水厂的功能是利用水泵将湖泊中的水抽取到所在城市的蓄水池中。
因此，只有与湖泊毗邻的第1 行的城市可以建造蓄水厂。而输水站的功能则是通过输水管线利用高度落差，将湖水从高处向低处输送。故一座城市能建造输水站的前提，是存在比它海拔更高且拥有公共边的相邻城市，已经建有水利设施。由于第N 行的城市靠近沙漠，是该国的干旱区，所以要求其中的每座城市都建有水利设施。那么，这个要求能否满足呢？如果能，请计算最少建造几个蓄水厂；如果不能，求干旱区中不可能建有水利设施的城市数目。

输入格式：

输入文件的每行中两个数之间用一个空格隔开。输入的第一行是两个正整数N 和M，表示矩形的规模。接下来N 行，每行M 个正整数，依次代表每座城市的海拔高度。

输出格式：

输出有两行。如果能满足要求，输出的第一行是整数 1，第二行是一个整数，代表最少建造几个蓄水厂；如果不能满足要求，输出的第一行是整数0，第二行是一个整数，代表有几座干旱区中的城市不可能建有水利设施。

题解：

这个题解是转载的，能力不足。
如果能够满足要求，可以证明一个结论：每个蓄水站所覆盖到的城市是连接的，若中间有断开，则断开的点一定高于左右，若比之上方的点低，则其上方的点一定高于其左右，而起始点又是可以通过一条路到达右边被断开的区域的，则断开的点一定不能被其他点管辖.那么就成了最少线段覆盖问题，可以用dp解决.记录每个蓄水站能到达的左右点l[i],r[i],那么f[i] = min(f[i],f[l[j] - 1] + 1);点i必须要在l[j]到r[j]内.其实这道题用一个dfs就可以解决，不过为了方便，还是用了3个dfs.
搜了1年，才发现是DP。

代码：

var
  n,m,ans:longint;
  map:array [0..501,0..501] of longint;
  l,r,f:array [0..501] of longint;
  v:array [0..501,0..501] of boolean;
function min(o,p:longint):longint;
begin
  if o<p then exit(o);
  exit(p);
end;

procedure dfs1(x,y:longint);
begin
  if v[x,y] then exit;
  v[x,y]:=true;
  if (x+1<=n) and (map[x,y]>map[x+1,y]) then dfs1(x+1,y);
  if (x-1>=1) and (map[x,y]>map[x-1,y]) then dfs1(x-1,y);
  if (y+1<=m) and (map[x,y]>map[x,y+1]) then dfs1(x,y+1);
  if (y-1>=1) and (map[x,y]>map[x,y-1]) then dfs1(x,y-1);
end;

procedure init;
var
  i,j:longint;
begin
  readln(n,m);
  for i:=1 to n do
    for j:=1 to m do
      read(map[i,j]);
  ans:=0;
  for i:=1 to m do
    dfs1(1,i);
  for i:=1 to m do
    if v[n,i]=false then inc(ans);
  if ans>0 then
    begin
      writeln('0');
      write(ans);
      halt;
    end;
end;

procedure dfs2(x,y,z:longint);
begin
  if v[x,y] then exit;
  if x=1 then l[y]:=z;
  v[x,y]:=true;
  if (x+1<=n) and (map[x,y]<map[x+1,y]) then dfs2(x+1,y,z);
  if (x-1>=1) and (map[x,y]<map[x-1,y]) then dfs2(x-1,y,z);
  if (y+1<=m) and (map[x,y]<map[x,y+1]) then dfs2(x,y+1,z);
  if (y-1>=1) and (map[x,y]<map[x,y-1]) then dfs2(x,y-1,z);
end;

procedure dfs3(x,y,z:longint);
begin
  if v[x,y] then exit;
  if x=1 then r[y]:=z;
  v[x,y]:=true;
  if (x+1<=n) and (map[x,y]<map[x+1,y]) then dfs3(x+1,y,z);
  if (x-1>=1) and (map[x,y]<map[x-1,y]) then dfs3(x-1,y,z);
  if (y+1<=m) and (map[x,y]<map[x,y+1]) then dfs3(x,y+1,z);
  if (y-1>=1) and (map[x,y]<map[x,y-1]) then dfs3(x,y-1,z);
end;

procedure main;
var
  i,j:longint;
begin
  fillchar(v,sizeof(v),false);
  for i:=1 to m do
    dfs2(n,i,i);
  fillchar(v,sizeof(v),false);
  for i:=m downto 1 do
    dfs3(n,i,i);
  fillchar(f,sizeof(f),63);
  f[0]:=0;
  for i:=1 to m do
    for j:=1 to m do
      if (l[j]<=i) and (r[j]>=i) then
        f[i]:=min(f[i],f[l[j]-1]+1);
  writeln('1');
  write(f[m]);
end;

begin
  init;
  main;
end.