poj 2182 Lost Cows 线段树

题意/Description：

  N (2 <= N <= 8,000) cows have unique brands in the range 1..N. In a spectacular display of poor judgment, they visited the neighborhood 'watering hole' and drank a few too many beers before dinner. When it was time to line up for their evening meal, they did not line up in the required ascending numerical order of their brands. 

  Regrettably, FJ does not have a way to sort them. Furthermore, he's not very good at observing problems. Instead of writing down each cow's brand, he determined a rather silly statistic: For each cow in line, he knows the number of cows that precede that cow in line that do, in fact, have smaller brands than that cow. 

  Given this data, tell FJ the exact ordering of the cows. 

 

读入/Input：

  Line 1: A single integer, N 
  Lines 2..N: These N-1 lines describe the number of cows that precede a given cow in line and have brands smaller than that cow. Of course, no cows precede the first cow in line, so she is not listed. Line 2 of the input describes the number of preceding cows whose brands are smaller than the cow in slot #2; line 3 describes the number of preceding cows whose brands are smaller than the cow in slot #3; and so on. 

 

输出/Output：

  Lines 1..N: Each of the N lines of output tells the brand of a cow in line. Line #1 of the output tells the brand of the first cow in line; line 2 tells the brand of the second cow; and so on.

 

题解/solution：

  用线段树。关键：每次最后一只牛的编号是可以确定的，即为pre[i]+1，将其编号从所有牛中删除，则倒数第二只牛的编号又可以确定为pei[i]+1，依此类推。和poj 2828很像。

 

代码/Code：

<strong>type
  arr=record
    l,r,len:longint;
  end;
var
  n:longint;
  tree:array [0..400001] of arr;
  ap,ans:array [0..100001] of longint;
procedure cre(p,b,e:longint);
var
  m:longint;
begin
  with tree[p] do
    begin
      l:=b; r:=e; len:=e-b+1;
      if b=e then exit;
      m:=(b+e) div 2;
      cre(p*2,b,m);
      cre(p*2+1,m+1,e);
    end;
end;

function count(p,num:longint):longint;
begin
  with tree[p] do
    begin
      dec(len);
      if l=r then exit(l);
      if tree[p*2].len<num then
        exit(count(p*2+1,num-tree[p*2].len));
      if tree[p*2].len>=num then
        exit(count(p*2,num));
    end;
end;

procedure main;
var
  i:longint;
begin
  readln(n);
  ap[1]:=0;
  for i:=2 to n do
    readln(ap[i]);
  cre(1,1,n);
  for i:=n downto 1 do
    ans[i]:=count(1,ap[i]+1);
  for i:=1 to n do
    writeln(ans[i]);
end;

begin
  main;
end.</strong>