调整图像 自动对比度、自动色阶算法

　　我们以24位彩色图像为例说明这两个算法。

　　在执行两个算法之前，我们需要确定两个参数，大家在用PS时选择自动色阶并不会弹出什么参数设置对话框，那是因为PS把这个隐藏的比较深 。选择曲线或色阶命令，然后在弹出的界面中点击选项按钮，会出现如下界面：

   

　　注意其中的裁剪(C)/裁剪(P)中的变量，这两个参数是影响自动色阶效果的重要数据，我们以变量LowCut和HighCut来记录它。

     好，接着说。两个算法的第一步，都是分别统计各通道（红/绿/蓝）的直方图。

 1     Dim HistRed(255)        As Long, HistGreen(255)        As Long
 2     Dim HistBlue(255)       As Long
 3     For Y = 0 To Height - 1
 4         Speed = Y * Stride
 5         For X = 0 To Width - 1
 6             Red = ImageData(Speed + 2): Green = ImageData(Speed + 1): Blue = ImageData(Speed)
 7             HistRed(Red) = HistRed(Red) + 1                 '统计直方图
 8             HistGreen(Green) = HistGreen(Green) + 1
 9             HistBlue(Blue) = HistBlue(Blue) + 1
10             Speed = Speed + 3
11         Next
12     Next

      看了上面代码，我很欣赏C++的++运算符，HistRed(Red)++，多么简单啊，而且更高效。

      算法的第二步，分别计算各通道按照给定的参数所确定的上下限值。什么意思呢，比如对于蓝色通道，我们从色阶0开始向上累加统计直方图，当累加值大于LowCut*所有像素数时，以此时的色阶值计为MinBlue。然后从色阶255开始向下累计直方图，如果累加值大于HighCut*所有像素时，以此时的色阶值计为MaxBlue。

 1     PixelAmount = Width * Height                     '所有像素的数目
 2     Sum = 0
 3     For Y = 0 To 255
 4         Sum = Sum + HistBlue(Y)
 5         If Sum >= PixelAmount * LowCut * 0.01 Then   '注意PS界面里的那个百分号
 6             MinBlue = Y                              '得到蓝色分量的下限
 7             Exit For                                 '退出循环
 8         End If
 9     Next
10     
11     Sum = 0
12     For Y = 255 To 0 Step -1
13         Sum = Sum + HistBlue(Y)
14         If Sum >= PixelAmount * HighCut * 0.01 Then  '注意PS界面里的那个百分号
15             MaxBlue = Y                              '得到蓝色分量的上限
16             Exit For                                 '退出循环
17         End If
18     Next

      绿色通道和红色通道的代码类似，请朋友们自己补充。

      下一步，自动色阶和自动对比度就有所区别了，我们首先介绍自动色阶。

      自动色阶：按照我们刚刚计算出的MinBlue/MaxBlue构建一个隐射表，隐射表的规则是，对于小于MinBlue的值，则隐射为0（实际上这句话也不对，隐射为多少是和那个自动颜色校正选项对话框中的阴影所设定的颜色有关，默认情况下是黑色，对应的RGB分量都为0，所以我们这里就隐射为0，有兴趣你们也可以指定为其他的参数），对于大于MaxBlue的值，则隐射为255（同理，这个值和高光的颜色设置有关），对于介于MinBlue和MaxBlue之间的值，则进行线性隐射，默认是隐射为0到255之间(当然实际是和我们的暗调和高光的设置有关，并且这里其实也不是线性隐射，是有一个Gamma校正，为了简便，用线性替代效果也没太大的问题）。

     For Y = 0 To 255
2         If Y <= MinBlue Then
3             BlueMap(Y) = 0
4         ElseIf Y >= MaxBlue Then
5             BlueMap(Y) = 255
6         Else
7             BlueMap(Y) = (Y - MinBlue) / (MaxBlue - MinBlue) * 255      '线性隐射
8         End If
9     Next

      顺便提一点，从程序的鲁棒性上来说，在执行这段代码前判断下MaxBlue是否等于MinBlue很有必要，两者相等，这图就无需校正了，直接结束程序。

      用同样的道理，计算出绿色和红色通道的隐射表GreenMap和RedMap。

      最后一步，对各通道图像数据进行隐射。

     For Y = 0 To Height - 1
2         Speed = Y * Stride
3         For X = 0 To Width - 1
4             ImageData(Speed) = BlueMap(ImageData(Speed))
5             ImageData(Speed + 1) = GreenMap(ImageData(Speed + 1))
6             ImageData(Speed + 2) = RedMap(ImageData(Speed + 2))
7             Speed = Speed + 3
8         Next
9     Next

       自动色阶完成，下面我们谈谈自动对比度的不同。

       在计算完各通道对应的上下限值后，自动对比度算法首先获取三个通道下限值的最小值，以及上限值的最大值，如下代码：

 1     If MinBlue < MinGreen Then
 2         Min = MinBlue
 3     Else
 4         Min = MinGreen
 5     End If
 6     If Min > MinRed Then Min = MinRed
 7     
 8     If MaxBlue > MaxGreen Then
 9         Max = MaxBlue
10     Else
11         Max = MaxGreen
12     End If
13     If Max < MaxRed Then Max = MaxRed

 　　然后以此为新的上下限，计算隐射表。

     For Y = 0 To 255
2         If Y <= Min Then
3             Map(Y) = 0
4         ElseIf Y > Max Then
5             Map(Y) = 255
6         Else
7             Map(Y) = (Y - Min) / (Max - Min) * 255      '线性隐射
8         End If
9     Next

      最后，以这个隐射表分别对红绿蓝通道进行处理。

     For Y = 0 To Height - 1
2         Speed = Y * Stride
3         For X = 0 To Width - 1
4             ImageData(Speed) = Map(ImageData(Speed))
5             ImageData(Speed + 1) = Map(ImageData(Speed + 1))
6             ImageData(Speed + 2) = Map(ImageData(Speed + 2))
7             Speed = Speed + 3
8         Next
9     Next

　　 由以上过程可以看出，对于灰度图像，由于只有一个通道，自动对比度和自动色阶实际上算法相同，结果一样。

       对于32位图像，这类单点像素处理的过程一般是无需处理Alpha通道的。