REPLACEF

     参考网址:http://www.oracle-developer.net/content/utilities/replacef.sql

     A function to simplify string building and debugging by replacing multiple placeholders from a collection of inputs. 

定义集合的类型:

CREATE OR REPLACE TYPE replacef_ntt AS TABLE OF VARCHAR2(4000);

函数:

CREATE OR REPLACE FUNCTION replacef(p_msg  IN VARCHAR2, --SQL语句
                                    p_args IN replacef_ntt DEFAULT replacef_ntt(), --要替换的参数集合
                                    p_plc  IN VARCHAR2 DEFAULT '%s') --默认的替代符
 RETURN VARCHAR2 IS

  v_msg  VARCHAR2(32767) := p_msg; --SQL语句
  v_args PLS_INTEGER := least((length(v_msg) -
                              length(REPLACE(v_msg, p_plc))) *
                              length(p_plc),
                              p_args.count);
  --替代符的个数:需要根据SQL语句和传递的集合计算出具体的需要替换的个数，
  --取她们中的小的，作为替换的个数
  /**
   与least函数相对应的含有greaste函数
  **/
  v_pos PLS_INTEGER; --位置变量

BEGIN

  FOR i IN 1 .. v_args LOOP
    v_pos := instr(v_msg, p_plc);
    --dbms_output.put_line(v_pos);
    --拆分为两半:前一半进行替换后和后一半拼接上去
    v_msg := REPLACE(substr(v_msg, 1, v_pos + length(p_plc) - 1),
                     p_plc,
                     p_args(i)) || substr(v_msg, v_pos + length(p_plc));
    --dbms_output.put_line(substr(v_msg, 1, v_pos + length(p_plc) - 1));
    --dbms_output.put_line(p_args(i) || substr(v_msg, v_pos + length(p_plc)));
    --dbms_output.put_line(v_msg);
  END LOOP;

  RETURN v_msg;

END replacef;

测试1:

DECLARE
  v_sql   VARCHAR2(128);
  nt_args replacef_ntt := replacef_ntt();
BEGIN
  v_sql   := 'ALTER TABLE %s.%s TRUNCATE PARTITION %s';
  nt_args := replacef_ntt('table_owner', 'table_name', 'partition_name');
  dbms_output.put_line(replacef(v_sql, nt_args));
END;

结果:ALTER TABLE table_owner.table_name TRUNCATE PARTITION partition_name

测试2:

SELECT replacef('ALTER TABLE %s.%s TRUNCATE PARTITION %s',
                replacef_ntt('table_owner', 'table_name', 'partition_name')) results
  FROM dual

测试:3

DECLARE
  v_sql   VARCHAR2(128);
  nt_args replacef_ntt := replacef_ntt();
BEGIN
  v_sql   := 'ALTER TABLE %s.%s TRUNCATE PARTITION %s';
  nt_args := replacef_ntt('table_owner', 'table_name', 'partition_name');
  v_sql   := replacef(v_sql, nt_args);
  EXECUTE IMMEDIATE v_sql;--动态执行结果
END;

--end