Bulk SQL Operations

       PL/SQL中的批量操作，允许一次操作和处理多行数据，而不是一次处理一行数据。批量操作包括批量的读取数据，批量的绑定处理处理数据:( bulk fetching and bulk binding)

      Bulk fetching refers to the ability to retrieve a set of rows from the database into PL/SQL structures with a single call, rather than making a call to the database for each row to be retrieved.

      Bulk binding lets you perform the converse: to take those sets of rows stored in
PL/SQL structures and save them to the database in an efficient manner.
   

-------------------------------------------------------------------------------------------------

     Getting Started with BULK Fetch

在PL/SQL中，有三种方法获取行记录:

1、Implicit Cursor

    SELECT INTO

    (当没有查询到记录，或者查询到的记录多于一行会抛出异常--NO_DATA_FOUND和TO_MANY_ROWS)

DECLARE
  l_Descr Hardware.Descr%TYPE;
BEGIN
  SELECT Descr
    INTO l_Descr
    FROM Hardware
   WHERE Aisle = 1
     AND Item = 1;
END;

2. Explicit Fetch Calls(手动i打开游标，进行游标的关闭和读取数据)

DECLARE
  CURSOR c_Tool_List IS
    SELECT Descr
      FROM Hardware
     WHERE Aisle = 1
       AND Item BETWEEN 1 AND 500;
  l_Descr Hardware.Descr%TYPE;
BEGIN
  OPEN c_Tool_List;
  LOOP
    FETCH c_Tool_List
      INTO l_Descr;
    EXIT WHEN c_Tool_List%NOTFOUND;
  END LOOP;
  CLOSE c_Tool_List;
END;

3、Implicit Fetch Calls(FOR LOOP循环，游标FOR循环--推荐使用，因为不要进行游标的关闭等)

BEGIN
  FOR i IN (SELECT Descr
              FROM Hardware
             WHERE Aisle = 1
               AND Item BETWEEN 1 AND 500) LOOP
  <processing code for each row>
  END LOOP;
END;

 上述三种情况对应的批量读取数据:

1. Implicit Cursor BULK Mode：SELECT  BULK COLLECT INTO

DECLARE
  TYPE t_Descr_List IS TABLE OF Hardware.Descr%TYPE;
  l_Descr_List t_Descr_List;
BEGIN
  SELECT Descr BULK COLLECT
    INTO l_Descr_List
    FROM Hardware
   WHERE Aisle = 1
     AND Item BETWEEN 1 AND 100;
END;

2. Explicit Fetch Calls BULK Mode:FETCH BULK COLLECT INTO

DECLARE
  CURSOR c_Tool_List IS
    SELECT Descr
      FROM Hardware
     WHERE Aisle = 1
       AND Item BETWEEN 1 AND 500;
  TYPE t_Descr_List IS TABLE OF c_Tool_List%ROWTYPE;
  l_Descr_List t_Descr_List;
BEGIN
  OPEN c_Tool_List;
  FETCH c_Tool_List BULK COLLECT
    INTO l_Descr_List;
  CLOSE c_Tool_List;
END;

在这种情况下，假如使用LIMIT参数，限制每次处理的记录条数:

DECLARE
  TYPE Numtab IS TABLE OF NUMBER INDEX BY PLS_INTEGER;
  CURSOR C1 IS
    SELECT Employee_Id FROM Employees WHERE Department_Id = 80;
  Empids Numtab;
  Rows   PLS_INTEGER := 10;
BEGIN
  OPEN C1;
  -- Fetch 10 rows or less in each iteration
  LOOP
    FETCH C1 BULK COLLECT
      INTO Empids LIMIT Rows;
    EXIT WHEN Empids.Count = 0;
    -- EXIT WHEN c1%NOTFOUND; -- incorrect, can omit some data
    Dbms_Output.Put_Line('------- Results from Each Bulk Fetch --------');
    FOR i IN 1 .. Empids.Count LOOP
      Dbms_Output.Put_Line('Employee Id: ' || Empids(i));
    END LOOP;
  END LOOP;
  CLOSE C1;
END;

使用

EXIT WHEN c1%NOTFOUND、使用该语句退出集合存在问题，因为他可能会忽略一些记录，
应该使用

EXIT WHEN Empids.Count = 0;来进行游标FOR循环的退出。
但是也可以在自己的业务处理完毕之后，使用

 EXIT WHEN c1%NOTFOUND;来退出集合

3、Implicit Fetch Calls BULK mode

BEGIN
  FOR i IN (SELECT Descr
              FROM Hardware
             WHERE Aisle = 1
               AND Item BETWEEN 1 AND 500) LOOP
    NULL;
  END LOOP;
END;

三种形式的集合:

            • Varray
            • Nested table
            • Associative array

   

-------------------------------------------------------------------------------------------------

     Getting Started with BULK Fetch

:FORALL的例子

DECLARE
  TYPE t_Row_List IS TABLE OF Hardware%ROWTYPE;
  l_Row t_Row_List := t_Row_List();
BEGIN
  FOR i IN 1 .. 100 LOOP
    l_Row.Extend;
    l_Row(i).Aisle := 1;
    l_Row(i).Item := i;
  END LOOP;
  FORALL i IN 1 .. 100
    INSERT INTO Hardware VALUES l_Row (i);
END;

批量处理的标准步骤:

   场景1:Elements Do Not Start at 1,序号没有从1开始，但是他还是连续的，可以使用.FIRST和.LAST作为循环的开始和结束:

DECLARE
  TYPE t_Num_List IS TABLE OF Hardware.Item%TYPE INDEX BY PLS_INTEGER;
  Val t_Num_List;
BEGIN
  Val(10) := 10;
  Val(11) := 20;
  Val(12) := 20;
  FORALL i IN Val.First .. Val.Last
    INSERT INTO Hardware (Item) VALUES (Val(i));
END;

场景2:Elements Are Not Contiguous,不联系的情况，可以使用Oracle提供的INDICES OF函数，

DECLARE
  TYPE t_Num_List IS TABLE OF Hardware.Item%TYPE INDEX BY PLS_INTEGER;
  Val t_Num_List;
BEGIN
  Val(10) := 10;
  -- val(11) := 20;
  Val(12) := 20;
  FORALL i IN INDICES OF Val
    INSERT INTO Hardware (Item) VALUES (Val(i));
END;

        I recommend adopting a standard of using the INDICES OF clause whenever you want to process an entire collection, and that use of .FIRST, .LAST, and .COUNT should be deprecated in your PL/SQL code. Sadly, the INDICES OF extension can only be used in a FORALL  statement, not in a standard FOR loop.(推荐在你的代码中使用INDICES OF来处理整个集合,FIRST,LAST,COUNT在你的PL/SQL编码不应该在出现，不幸的是，INDICES OF只可以用在FORALL自居中，不能使用在标准的LOOP循环中。)

VALUES OF使用:

DECLARE
  TYPE t_Input_Row IS RECORD(
    Item   Hardware.Item%TYPE,
    Descr  Hardware.Descr%TYPE,
    Status VARCHAR2(3));
  TYPE t_Input_List IS TABLE OF t_Input_Row INDEX BY PLS_INTEGER;
  Src t_Input_List;
  TYPE t_Target_Indices IS TABLE OF PLS_INTEGER INDEX BY PLS_INTEGER;
  Ind_New t_Target_Indices;
  Ind_Upd t_Target_Indices;
BEGIN
  FOR i IN 1 .. 100 LOOP
    Src(i).Item := i;
    Src(i).Descr := 'Item ' || i;
    Src(i).Status := CASE
                       WHEN MOD(i, 5) = 0 THEN
                        'NEW'
                       ELSE
                        'UPD'
                     END;
  END LOOP;
  FOR i IN 1 .. 100 LOOP
    IF Src(i).Status = 'NEW' THEN
      Ind_New(Ind_New.Count) := i;
    ELSE
      Ind_Upd(Ind_Upd.Count) := i;
    END IF;
  END LOOP;
  FORALL i IN VALUES OF Ind_New
    INSERT INTO Hardware (Aisle, Item) VALUES (1, Src(i).Item);
  Dbms_Output.Put_Line(SQL%ROWCOUNT || ' rows inserted');
  FORALL i IN VALUES OF Ind_Upd
    UPDATE Hardware
       SET Descr = Src(i).Descr
     WHERE Aisle = 1
       AND Item = Src(i).Item;
  Dbms_Output.Put_Line(SQL%ROWCOUNT || ' rows updated');
END;

--具体请参考:

<<Expert_PL_SQL_Practices_for_Oracle_Developers_and_DBAs>>:

Chapter 6: Bulk SQL Operations