[SQL Utility]Tom’s PRINT_TABLE

默认的Select 语句的显示结果是把表中的每一条记录显示成一行，如果表的列数很多会带来一个问题（求其是在SQL*PLUS中），那就是要么列名显示不全，或者会折成很多行来显示，造成阅读上的不便。 如果我们只是很关心这种多列表中的特定一行或几行数据，如果可以把显示结果“转置”过来，每一行显示一个列的数据，这样会大大有助于阅读，分析数据。

多说无益，还是上例子说明。 如下，

 

默认的显示

SQL> select * from t where rownum = 1;

        N1         N2         N3         N4         N5
---------- ---------- ---------- ---------- ----------
        10         20         30        200         30

====》

转换后的显示

N1                            : 10
N2                            : 20
N3                            : 30
N4                            : 200
N5                            : 30
-----------------

Tom 很早就给出了这样一个解决方法，参见这里

具体代码如下：

create or replace procedure print_table( p_query in varchar2 )
AUTHID CURRENT_USER
is
    l_theCursor     integer default dbms_sql.open_cursor;
    l_columnValue   varchar2(4000);
    l_status        integer;
    l_descTbl       dbms_sql.desc_tab;
    l_colCnt        number;
begin
    execute immediate
    'alter session set
        nls_date_format=''dd-mon-yyyy hh24:mi:ss'' ';

    dbms_sql.parse(  l_theCursor,  p_query, dbms_sql.native );
    dbms_sql.describe_columns
    ( l_theCursor, l_colCnt, l_descTbl );

    for i in 1 .. l_colCnt loop
        dbms_sql.define_column
        (l_theCursor, i, l_columnValue, 4000);
    end loop;

    l_status := dbms_sql.execute(l_theCursor);

    while ( dbms_sql.fetch_rows(l_theCursor) > 0 ) loop
        for i in 1 .. l_colCnt loop
            dbms_sql.column_value
            ( l_theCursor, i, l_columnValue );
            dbms_output.put_line
            ( rpad( l_descTbl(i).col_name, 30 )
              || ': ' ||
              l_columnValue );
        end loop;
        dbms_output.put_line( '-----------------' );
    end loop;
    execute immediate
        'alter session set nls_date_format=''dd-MON-rr'' ';
exception
    when others then
      execute immediate
          'alter session set nls_date_format=''dd-MON-rr'' ';
      raise;
end;
/

用法很简单，

SQL> set serveroutput on
SQL> exec print_table('select * from t where rownum <= 2');
N1                            : 10
N2                            : 20
N3                            : 30
N4                            : 200
N5                            : 30
-----------------
N1                            : 10
N2                            : 1
N3                            : 11
N4                            : 10
N5                            : 11
-----------------

PL/SQL procedure successfully completed.

SQL>