AS3随鼠标移动的蜘蛛

package antCodes
{
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.events.MouseEvent;
    
    /**
     * ...
     * @getDefinitionByName(name:String):Object
     *  这是一个接口，返回name参数指定的类对象的引用
     * @author Dong
     */
    public class SampleSpider extends Sprite
    {
        private var _Spider:Class;//蜘蛛对象
        private var spider:MovieClip;
        private var line:Sprite;//蜘蛛爬行的线
        private var speed:Number = 10;//爬行速度
        
        public function SampleSpider(){
            initView();
            this.addEventListener(Event.ENTER_FRAME, drawLine);
            this.addEventListener(Event.ENTER_FRAME, moveSpider);
            //鼠标点击后，停止侦听ENTER_FRAME事件
            this.stage.addEventListener(MouseEvent.CLICK, stopAnimation);
        }        
        private function initView():void {
            //获取库元件自动绑定的类
            _Spider =getDefinitionByName("Spider_mc") as Class;
            //生成线的容器
            line = new Sprite();
            addChild(line);
            //实例化显示对象
            spider = new _Spider();
            addChild(spider);
            spider.cacheAsBitmap = true; //打开位图缓存，提高执行效率
            
        }
        //在每帧中，重新绘制蛛丝
        private function drawLine(evt:Event):void {
            line.graphics.clear();        //清空
            line.graphics.moveTo(0, 0);        
            line.graphics.lineStyle(1, 0xffffff);        
            line.graphics.lineTo(spider.x, spider.y);            
        }
        //在每帧中，移动和旋转蜘蛛
        private function moveSpider(evt:Event):void {
            var dx:Number = this.mouseX - spider.x;
            var dy:Number = this.mouseY - spider.y;
            //Math.atan():Number
            //以弧度为单位计算并返回角度值，该角度的正切值已在参数 val 中指定。
            var p:Number  =Math.atan(dy/dx)*180/Math.PI;//计算弧度
            var rotateAngle:Number = (dx>0) ? (90+p):(270+p);//旋转角度
            spider.x += dx/speed;
            spider.rotation = rotateAngle;
            spider.y += dy/speed;
        }
        private function stopAnimation(evt:MouseEvent):void {
            this.removeEventListener(Event.ENTER_FRAME, drawLine);
            this.removeEventListener(Event.ENTER_FRAME, moveSpider);
        }
    }
}