[ActionScript 3.0] 结合FMS实现简单视频录制

首先在本机上安装Flash Media Server，简称FMS，在测试过程中window防火墙开启可能有影响，可先关闭防火墙，FMS安装好后检查相关服务有没有启动，若没有，可启动任务管理器，点击服务，将Flash Media Server(FMS)   Flash Media

Administration Server  FMSHttpd 手动启动，一切就绪后，把以下as类作为文档类，就可测试了。

package 
{
    import flash.display.Sprite;
    import flash.events.NetStatusEvent;
    import flash.events.StatusEvent;
    import flash.media.Camera;
    import flash.media.Microphone;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    /**
      * ...
      * @author FrostYen
      */
    public class Main extends Sprite
    {
        private var netConn:NetConnection;
        private var netStream:NetStream;
        private var camera:Camera;
        private var video:Video;
        private var rtmp:String;
        private var microphpne:Microphone;
        public function Main()
        {
            init();
        }

        private function init():void
        {
            //初始化一个网络连接 
            netConn = new NetConnection  ;
            //为这个连接添加事件,这个事件有返回连接状态 
            netConn.addEventListener(NetStatusEvent.NET_STATUS,onNetStatus);
            //这是连接的地址,其实就是在你FMS的安装目录里,Applications下新建一个yan的文件夹,录制的视频会保存在这个yan文件夹下自动生成的streams/_definst_文件夹下，
            rtmp = "rtmp://127.0.0.1/yan/";
            //开始连接
            netConn.connect(rtmp);
            //获取系统的microphone    ;
            microphpne = Microphone.getMicrophone();
            microphpne.setLoopBack(true);
            //获取系统的摄像头;
            camera = Camera.getCamera();
            if ((camera == null))
            {
                trace("未检测到摄像头");
            }
            else
            {

                //设定宽,高,以及帧频
                camera.setMode(240,180,24);
                //设定画面质量 
                //cam.setQuality(0,90);
                video = new Video  ;
                video.attachCamera(camera);
                this.addChild(video);
                camera.addEventListener(StatusEvent.STATUS,onCameraStatus);
            }
        }
        //重要说明： 当引用或者创建Camera和Microphone对象时，Flash Player 将显示“隐私”对话框，用户可从中选择是允许还是拒绝访问摄像头和麦克风。 请确保应用程序窗口大小至少为 215 x 138 像素，这是显示对话框所需的最小尺寸。
        private function onCameraStatus(e:StatusEvent):void
        {

            //status:StatusEvent — 在摄像头报告其状态时调度。 如果 code 属性的值为“Camera.Muted”，则表示用户拒绝 SWF 文件访问其摄像头。 如果 code 属性的值为“Camera.Unmuted”，则表示用户允许 SWF 文件访问其摄像头。
            switch (e.code)
            {
                case "Camera.Unmuted" ://Camera access was allowed

                    break;
                case "Camera.Muted" ://Camera access was denied

                    break;
            }
        }

        private function onNetStatus(e:NetStatusEvent):void
        {
            //trace(e.info.code);
            switch (e.info.code)
            {
                case "NetConnection.Connect.Success" :
                    trace("链接成功");
                    if ((netStream != null))
                    {
                        netStream.close();
                    }
                    //建立一个流,为以后的录制传输数据
                    netStream = new NetStream(netConn);
                    camera.setQuality(163854,100);
                    //设置视频质量;
                    netStream.attachCamera(camera);
                    //录制视频      ;
                    netStream.attachAudio(microphpne);
                    //录制声音      ;
                    //netStream.publish("videoName","live");//直播
                    //netStream.publish("videoName","append");//追加性录制
                    netStream.publish("videoName","record");
                    //覆盖性录制;
                    break;
                case "NetConnection.Connect.Rejected" :
                    trace("没有权限");
                    break;
                default :
                    trace("连接服务器失败");
            }
        }

    }

}