[ActionScript 3.0] AS3调用百度地图API

package
{
    import baidu.map.basetype.LngLat;
    import baidu.map.basetype.Size;
    import baidu.map.config.Anchor;
    import baidu.map.control.base.Navigator;
    import baidu.map.control.base.Overview;
    import baidu.map.control.base.Ruler;
    import baidu.map.control.base.Scaler;
    import baidu.map.core.Map;
    import baidu.map.event.MapEvent;
    import baidu.map.layer.Layer;
    import baidu.map.layer.RasterLayer;
    
    import com.controls.TempMapControl;
    
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    
    /*************************************************************************************
     * Flash API为开发者提供了如下控件：                                                    
     * Control：控件的抽象基类，所有控件均继承此类的方法、属性。通过此类您可实现自定义控件。   
     * Navigator：地图平移控件，默认位于地图左上方，它包含控制地图平移的功能。
     * Scaler：地图缩放控件，默认位于地图左上方，它包含控制地图缩放的功能。
     * Overview：地图缩略图控件，默认位于地图右下方，是一个可折叠的缩略地图。
     * Ruler：地图比例尺控件，默认位于地图左下方，显示地图的比例关系。
     * Copyright：地图版权控件，默认位于地图左下方。
     *************************************************************************************
    /**
     * 测试百度地图API 
     * @author Frost.Yen
     * 
     */    
    public class BaiduMapTest extends Sprite
    {
        public function BaiduMapTest()
        {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            //创建一个大小为600*400的Map对象
            var map:Map = new Map(new Size(600,400));
            this.addChild(map);
            //初始化Map的中心点和显示级别（将地图的中心点坐标设置为经度116.404，纬度39.915。显示级别设置为12。）
            map.centerAndZoom(new LngLat(116.404,39.915),12);
            //添加底图（初始化图层，并添加到Map中。）
            var layer:Layer = new RasterLayer("BaiduMap",map);
            map.addLayer(layer);
            
            // 添加Navigator
            var nav:Navigator = new Navigator(map);
            map.addControl(nav);
            // 添加Overview            
            var overview:Overview = new Overview(map);
            map.addControl(overview);
            // 添加Scaler            
            var scaler:Scaler = new Scaler(map);
            map.addControl(scaler);
            // 添加Ruler            
            var ruler:Ruler = new Ruler(map);
            //ruler.anchor = Anchor.TL;//anchor表示控件的停靠位置
            //ruler.offset = new Size(50,20);//offset可以通过偏移量来指示控件距离地图边界有多少像素
            map.addControl(ruler);
            
            //添加自定义控件
            var temp:TempMapControl = new TempMapControl(map);
            map.addControl(temp);
            //为map添加事件
            map.addEventListener(MapEvent.CLICK,function(e:MapEvent):void{trace("click map")});
        }
    }
}

可以实现自定义Control控件;

package com.controls
{
    import baidu.map.basetype.Size;
    import baidu.map.config.Anchor;
    import baidu.map.control.Control;
    import baidu.map.core.IMap;
    
    import flash.events.Event;
    import flash.text.TextField;

    /**
     * 自定义Control控件
     * @author Frost.Yen
     * 
     */    
    public class TempMapControl extends Control
    {
        public function TempMapControl(map:IMap)
        {
            super(map);
            _offset = new Size(200,20);
            _anchor = Anchor.TC;
            _anchor = Anchor.BC;
            trace(_anchor);
        }
        
        override protected function create(evt:Event=null):void
        {
            var tf:TextField = new TextField();
            tf.autoSize = "left";
            tf.text = "temp control";
            addChild(tf);
        }
        
        override protected function destroy(evt:Event=null):void
        {
            super.destroy(evt);
        }
        
        override public function dispose():void
        {
            super.dispose();
        }
        
    }
}