SQL SERVER中行列转换

DECLARE @subject varchar(2000)
DECLARE @name varchar(2000)
DECLARE @colName varchar(500)  --声明@colName变量，获取列名科目
set @colName = ''

--INFORMATION_SCHEMA.COLUMNS数据库的表名称，获取表名为A_Table中列名不为name的其他列名,@colName=[Chinese],[Math],[English],[History],[Geography],[Organism],[Chymistry],
SELECT @colName=@colName+'['+COLUMN_NAME+'],' FROM INFORMATION_SCHEMA.COLUMNS WHERE TABLE_NAME='A_Table' AND COLUMN_NAME!='name'

--从表A_Table中获取字段Name的值,@name=[张三],[李四],[王五],[赵六],
select @name=LEFT(name,LEN(name)-1) from (select (SELECT '['+Name+'],' FROM A_Table FOR XML PATH('')) as name) as a

--@subject=[Chinese],[Math],[English],[History],[Geography],[Organism],[Chymistry]
select @subject=subString(@colName,1,len(@colName)-1)

--UNPIVOT用于列转行
--PIVOT用于将列值旋转为列名（即行转列）,语法是：PIVOT(聚合函数(列) FOR 列 in (…) )AS P
exec(
    '
    select * from
    (
        SELECT name,CAST(kemu as FLOAT) as kemu,科目 
        FROM A_Table as t
        unpivot(kemu for 科目 in('+@subject+')) as b
    ) as a
    pivot(sum(kemu) for name in('+@name+')) as b
    '
)

--原表A_Table
select * from A_Table

执行结果如下：

　　

转换后格式
科目	张三	李四	王五	赵六
Chinese	60	70	80	90
Chymistry	60	70	80	90
English	60	70	80	90
Geography	60	70	80	90
History	60	70	80	90
Math	60	70	80	90
Organism	60	70	80	90

原表数据格式
Name	Chinese	Math	English	History	Geography	Organism	Chymistry
张三	60	60	60	60	60	60	60
李四	70	70	70	70	70	70	70
王五	80	80	80	80	80	80	80
赵六	90	90	90	90	90	90	90