SQL分割字符串函数

SQL分割字符串函数SQL里类似Split的分割字符串函数
SQL对字符串的处理能力比较弱，比如我要循环遍历象1,2,3,4,5这样的字符串，如果用数组的话，遍历很简单，但是T-SQL不支持数组，所以处理下来比较麻烦。下边的函数，实现了象数组一样去处理字符串。
一.用临时表作为数组

/*
函 数 名：F_split
函数作用：分割字符串
函数参数：
    @c    ### 要分割的字符串
    @split    ### 分隔符号
示例：
    Select * From dbo.F_split('a,b,c,d',',')
    返回结果：
        a
        b
        c
        d
*/
CREATE FUNCTION F_split(@c     VARCHAR(2000), 
                        @split VARCHAR(2)) 
returns @t TABLE( 
  col VARCHAR(20)) 
AS 
  BEGIN 
      WHILE( Charindex(@split, @c) <> 0 ) 
        BEGIN 
            INSERT @t 
                   (col) 
            VALUES (Substring(@c, 1, Charindex(@split, @c) - 1)) 

            SET @c = Stuff(@c, 1, Charindex(@split, @c), '') 
        END 

      INSERT @t 
             (col) 
      VALUES (@c) 

      RETURN 
  END
Go

二、按指定符号分割字符串，返回分割后的元素个数，方法很简单，就是看字符串中存在多少个分隔符号，然后再加一，就是要求的结果

/*
函 数 名：Get_StrArrayLength
函数作用：返回分割字符串的长度
函数参数：
    @str    ### 要分割的字符串
    @split    ### 分隔符号
示例：
    Select dbo.Get_StrArrayLength('78,1,2,3',',')
    返回结果：
        4
*/
Select dbo.Get_StrArrayLength('78,1,2,3',',')
CREATE FUNCTION Get_StrArrayLength (@str   VARCHAR(1024),
                                    @split VARCHAR(10)
) 
returns INT 
AS 
  BEGIN 
      DECLARE @location INT 
      DECLARE @start INT 
      DECLARE @length INT 

      SET @str=Ltrim(Rtrim(@str)) 
      SET @location=Charindex(@split, @str) 
      SET @length=1 

      WHILE @location <> 0 
        BEGIN 
            SET @start=@location + 1 
            SET @location=Charindex(@split, @str, @start) 
            SET @length=@length + 1 
        END 

      RETURN @length 
  END
Go

三、按指定符号分割字符串，返回分割后指定索引的第几个元素，象数组一样方便

/*
函 数 名：Get_StrArrayStrOfIndex
函数作用：按指定符号分割字符串，返回分割后指定索引的第几个元素，象数组一样方便
函数参数：
    @str    ### 要分割的字符串
    @split    ### 分隔符号
    @index    ### 取第几个元素
示例：
    Select dbo.Get_StrArrayStrOfIndex('8,9,4',',',2)
    返回结果：
        9
*/
CREATE FUNCTION Get_StrArrayStrOfIndex(@str   VARCHAR(1024), 
                                        @split VARCHAR(10), 
                                        @index INT) 
returns VARCHAR(1024) 
AS 
  BEGIN 
      DECLARE @location INT 
      DECLARE @start INT 
      DECLARE @next INT 
      DECLARE @seed INT 

      SET @str=Ltrim(Rtrim(@str)) 
      SET @start=1 
      SET @next=1 
      SET @seed=Len(@split) 
      SET @location=Charindex(@split, @str) 

      WHILE @location <> 0 
            AND @index > @next 
        BEGIN 
            SET @start=@location + @seed 
            SET @location=Charindex(@split, @str, @start) 
            SET @next=@next + 1 
        END 

      IF @location = 0 
        SELECT @location = Len(@str) + 1 

      RETURN Substring(@str, @start, @location - @start) 
  END
Go