zoukankan      html  css  js  c++  java
  • 批处理集锦——(6)【转】批处理实现全盘搜索指定文件获取其完整路径方法大全

    【方案一】for /f + dir

    @echo off
    rem 指定待搜索的文件
    set "FileName=string.bat"
    
    echo 正在搜索,请稍候...
    
    for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
      
      if exist %%a: (
      
            for /f "delims=" %%b in ('dir /a-d /s /b "%%a:*%FileName%" 2^>nul') do (
    
            if /i "%%~nxb" equ "%FileName%" (
                echo,%%b
            )
          
        )
        
      )
      
    )

    【方案二】for /r(比 for /f + dir 效率高,但不会遍历隐藏文件)

    @echo off
    rem 指定待搜索的文件
    set "FileName=BatHome_Batcher.txt"
    echo 正在搜索,请稍候...
    for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
     if exist %%a: (
      pushd %%a:
      for /r %%b in (*%FileName%) do (
       if /i "%%~nxb" equ "%FileName%" (
        echo,%%b
       )
      )
      popd
     )
    )

    【方案三】WMIC(Win2000/WinXP HOME版、WinXP 精简版可能不支持)

    @echo off
    rem 指定待搜索的文件
    set "FileName=BatHome_Batcher.txt"
    echo 正在搜索,请稍候...
    for %%a in ("%FileName%") do (
     set "nName=%%~na"
     set "xName=%%~xa"
    )
    set "xName=%xName:~1%"
    for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
     echo,%%a
    )

    【方案四】使用 Windows7 系统自带的 where 命令

    @echo off
    rem 指定待搜索的文件
    set "FileName=BatHome_Batcher.txt"
    echo 正在搜索,请稍候...
    for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
     if exist %%a: (
      for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
       if /i "%%~nxb" equ "%FileName%" (
        echo,%%b
       )
      )
     )
    )

    出处:http://www.jb51.net/article/54791.htm

  • 相关阅读:
    CentOS6.0 yum php mcrypt 扩展安装问题
    WordPress入门系列之基本设置
    ./configure 配置文件时出错checking for g++... no
    锐捷硬件防火墙
    CentOS 安装php mcrypt和mbstring的扩展
    (转)在asp.net 2.0中使用SqlBulkCopy类迁移数据
    正则表达式对象&&String对象
    SQL Server 和 SQLite 时间函数汇总
    FreeBSD下nginx并支持php配置详解
    从Ports安装MySQL
  • 原文地址:https://www.cnblogs.com/lovelp/p/5720084.html
Copyright © 2011-2022 走看看