简单的缓冲区助手类

//代码修改于 ICS 网络通信控件 中的TBuff类

 

    在某些有性能要求的地方，我们会开辟一块缓冲区，也就是分配一块内存，数据在都在此内存中操作，避免频繁的内存分配释放操作。

尤其在写服务器端程序时，这点显得非常重要，如果是普通的客户端程序，本文所说的方法，就不要考虑了，毕竟是操作有些繁琐。

这个助手类的目的是提高性能，同时还有个特点，助手类内部会进行内存边界的检测，保证在往缓冲区内写数据的时候，不会发生溢出，

听过说 著名的“缓冲区溢出”攻击吧。另外一个特点是，缓冲区的大小是在创建的时候，一次分配好，而不能进行修改。目的是配合内存

池使用，减少内存碎片的产生。但类的内部提供了，动态改变缓冲区大小的功能。只不过在这里被屏蔽掉了。要恢复此功能，很简单

修改代码如下： 

 

unit WSockBuf;
interface
uses
  SysUtils;
type
  TFixedBuffer = class
  private
    FBuf      : Pointer;
    FBufSize  : Integer;
    FWrCount  : Integer;
    FRdCount  : Integer;
    procedure   SetBufSize(newSize : Integer);
   // function    Remove(Len : Integer) : Integer;
    function    Peek(var Len : Integer) : Pointer;
  public
    procedure   Clear();
    constructor Create(nSize : Integer=4096); virtual;
    destructor  Destroy; override;
    function    Write(Data : Pointer; Len : Integer) : Integer;
    function    WriteStr(const Data:string):Integer;
    function    Read(Data : Pointer; Len : Integer) : Integer;
    function    ReadStr(Len:Integer=0):string; //Len <=0,读取全部数据
  public
    property    Buf:Pointer read FBuf;
    property    Position:Integer read FWrCount;
    property    BufSize : Integer read FBufSize;// write SetBufSize;
  end;
implementation

{* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *}
constructor TFixedBuffer.Create(nSize : Integer);
begin
  inherited Create;
  FWrCount  := 0;
  FRdCount  := 0;
  SetBufSize(nSize);
end;

{* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *}
destructor TFixedBuffer.Destroy;
begin
    if Assigned(Buf) then
        FreeMem(Buf, FBufSize);
    inherited Destroy;
end;

{* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *}
procedure TFixedBuffer.SetBufSize(newSize : Integer);
var
    newBuf : Pointer;
begin
    if newSize <= 0 then
        newSize := 1514;
    if newSize = FBufSize then
        Exit;
    if FWrCount = FRdCount then begin
        { Buffer is empty }
        if Assigned(Buf) then
            FreeMem(Buf, FBufSize);
        FBufSize := newSize;
        GetMem(FBuf, FBufSize);
    end
    else begin
        { Buffer contains data }
        GetMem(newBuf, newSize);
        Move(Buf^, newBuf^, FWrCount);
        if Assigned(Buf) then
            FreeMem(Buf, FBufSize);
        FBufSize := newSize;
        FBuf      := newBuf;
    end;
end;

{* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *}
function TFixedBuffer.Write(Data : Pointer; Len : Integer) : Integer;
var
    Remaining : Integer;
    Copied    : Integer;
begin
    Remaining := FBufSize - FWrCount;
    if Remaining <= 0 then
        Result := 0
    else begin
        if Len <= Remaining then
            Copied := Len
        else
            Copied := Remaining;
        Move(Data^, (PChar(Buf) + FWrCount)^, Copied);
        FWrCount := FWrCount + Copied;
        Result  := Copied;
    end;
end;

{* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *}
function TFixedBuffer.Read(Data : Pointer; Len : Integer) : Integer;
var
    Remaining : Integer;
    Copied    : Integer;
begin
    Remaining := FWrCount - FRdCount;
    if Remaining <= 0 then
        Result := 0
    else begin
        if Len <= Remaining then
            Copied := Len
        else
            Copied := Remaining;
        Move((PChar(Buf) + FRdCount)^, Data^, Copied);
        FRdCount := FRdCount + Copied;
        if FRdCount = FWrCount then begin
            FRdCount := 0;
            FWrCount := 0;
        end;
        Result := Copied;
    end;
end;

{* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *}
function TFixedBuffer.Peek(var Len : Integer) : Pointer;
var
    Remaining : Integer;
begin
    Remaining := FWrCount - FRdCount;
    if Remaining <= 0 then begin
        Len    := 0;
        Result := nil;
    end
    else begin
        Len    := Remaining;
        Result := Pointer(PChar(Buf) + FRdCount);
    end;
end;
(*
function TFixedBuffer.Remove(Len : Integer) : Integer;
var
    Remaining : Integer;
    Removed   : Integer;
begin
    Remaining := FWrCount - FRdCount;
    if Remaining <= 0 then
        Result := 0
    else begin
        if Len < Remaining then
            Removed := Len
        else
            Removed := Remaining;
        FRdCount := FRdCount + Removed;
        if FRdCount = FWrCount then begin
            FRdCount := 0;
            FWrCount := 0;
        end;
        Result := Removed;
    end;
end;
*)
{* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *}
function TFixedBuffer.WriteStr(const Data: string): Integer;
begin
  Result := Write(Pointer(Data),Length(Data));
end;
function TFixedBuffer.ReadStr(Len: Integer): string;
begin
  if Len <= 0 then len := system.MaxLongint;
  Peek(Len);
  if Len > 0 then
  begin
    SetLength(Result,Len);
    Read(Pointer(Result),Len);
  end
  else Result := '';
end;
procedure TFixedBuffer.Clear;
begin
  FWrCount  := 0;
  FRdCount  := 0;
end;