[BZOJ1025] [SCOI2009]游戏 解题报告

Description

　　windy学会了一种游戏。对于1到N这N个数字，都有唯一且不同的1到N的数字与之对应。最开始windy把数字按顺序1，2，3，……，N写一排在纸上。然后再在这一排下面写上它们对应的数字。然后又在新的一排下面写上它们对应的数字。如此反复，直到序列再次变为1，2，3，……，N。 如： 1 2 3 4 5 6 对应的关系为 1->2 2->3 3->1 4->5 5->4 6->6 windy的操作如下 1 2 3 4 5 6 2 3 1 5 4 6 3 1 2 4 5 6 1 2 3 5 4 6 2 3 1 4 5 6 3 1 2 5 4 6 1 2 3 4 5 6 这时，我们就有若干排1到N的排列，上例中有7排。现在windy想知道，对于所有可能的对应关系，有多少种可能的排数。

　　题意是让我们求回归到原序列的置换次数，也就是对于这个置换的每一个循环大小的最小公倍数

　　如（123）（45）（6）

　　对于第一个循环回归需要3x次(x代表任意自然数)，第二个循环需要2x次，第三个循环需要x次

　　显然对于这样的置换答案是6次

　　有多少种可能的排数，也就是这个最小公倍数有多少种可能..?

　　看起来比较奇怪的问题...

　　我们用一个序列来表示最小公倍数

　　2  3   5   7   11...997

　　x1 x2  x3  x4  x5...x168

　　最小公倍数就是2^x1*3^x2*5^x3...997^x168（说白了就是质因数分解>w<)

　　对于每一个循环，它的大小质因数分解之后对于每个质因子的系数都<=上面的序列

　　然后原问题就是满足题意的x1,x2..x168有多少种

　　我们来考虑怎样才会不满足题意...

　　首先x1,x2..x168再小也无所谓，因为就算全为0也是满足题意的，剩下的都可以用1来补全

　　显然对于这些x最小的n就是2^x1+3^x2...+997^x168

　　因为一旦2出现了x1次，说明一定有一个循环的个数中含有2^x1这个因子，我们令其中一个等于这个

　　为了使n最小化，其它都不含2这个因子

　　另外加法比乘法代价小这个显然...

　　也就是说对于x序列的限制也就是2^x1+3^x2...997^x168<=n

　　非常眼熟...非常简单的01背包...

　　

/**************************************************************
    Problem: 1025
    User: mjy0724
    Language: Pascal
    Result: Accepted
    Time:112 ms
    Memory:8236 kb
****************************************************************/
 
program bzoj1025;
const maxn=1010;
var n,ans:int64;
    i,j,k:longint;
    p:array[-1..maxn]of int64;
    f:array[-1..maxn,-1..maxn]of int64;
    vis:array[-1..maxn]of boolean;
 
procedure Euler;
var i,j:longint;
begin
    fillchar(vis,sizeof(vis),true);
    p[0]:=0;
    for i:=2 to n do
    begin
        if vis[i] then
        begin
            inc(p[0]);
            p[p[0]]:=i;
        end;
        for j:=1 to p[0] do
        begin
            if i*p[j]>n then break;
            vis[i*p[j]]:=false;
            if i mod p[j]=0 then break;
        end;
    end;
end;
 
begin
    readln(n);
    Euler;
    fillchar(f,sizeof(f),0);
    f[0,0]:=1;
    for i:=1 to p[0] do
        for j:=0 to n do
        begin
                        f[i][j]:=f[i-1][j];
            k:=p[i];
            while k<=j do
            begin
                inc(f[i,j],f[i-1,j-k]);
                k:=k*p[i];
            end;
        end;
    ans:=0;
    for i:=0 to n do inc(ans,f[p[0],i]);
    writeln(ans);
end.