【UOJ228】基础数据结构练习题（线段树）

题意：在一个序列中支持以下操作：

1.区间加

2.区间开根向下取整

3.区间求和

n,m<=100000

思路：因为有区间开根的存在暴力更改会导致O(n)的时间复杂度

所以我们要特判两种情况（别问我我不知道为什么）

1.sqrt(max)=sqrt(min)

这种情况说明开根后这段区间都是一个数，等价于区间赋值

2.sqrt(max)-sqrt(min)=1 & max-min=1

这种情况下这段区间开根后减少的值相同，等价于区间减

加上这两个转化优化后就能过了，也许是前人的经验吧

var t:array[1..500000]of record
                          a,b,s,mx,mn:int64;
                         end;
    a:array[1..200000]of longint;
    n,m,i,x,y,z,p:longint;

function max(x,y:int64):int64;
begin
 if x>y then exit(x);
 exit(y);
end;

function min(x,y:int64):int64;
begin
 if x<y then exit(x);
 exit(y);
end;

procedure pushup(x:longint);
var l,r:longint;
begin
 l:=x<<1; r:=l+1;
 t[x].mx:=max(t[l].mx,t[r].mx);
 t[x].mn:=min(t[l].mn,t[r].mn);
 t[x].s:=t[l].s+t[r].s;
end;

procedure add2(l,r:longint;v:int64;x:longint);
begin
 t[x].mx:=t[x].mx+v;
 t[x].mn:=t[x].mn+v;
 t[x].s:=t[x].s+v*(r-l+1);
 t[x].a:=t[x].a+v;
end;

procedure set1(l,r:longint;v:int64;x:longint);
begin
 t[x].mx:=v;
 t[x].mn:=v;
 t[x].s:=v*(r-l+1);
 t[x].b:=v;
 t[x].a:=0;
end;

procedure pushdown(l,r,x:longint);
var mid:longint;
begin
 if l=r then
 begin
  t[x].a:=0;
  exit;
 end;
 if t[x].b<>0 then
 begin
  mid:=(l+r)>>1;
  set1(l,mid,t[x].b,x<<1);
  set1(mid+1,r,t[x].b,x<<1+1);
  t[x].b:=0;
 end;
 if t[x].a<>0 then
 begin
  mid:=(l+r)>>1;
  add2(l,mid,t[x].a,x<<1);
  add2(mid+1,r,t[x].a,x<<1+1);
  t[x].a:=0;
 end;
end;

procedure build(l,r,p:longint);
var mid:longint;
begin
 if l=r then
 begin
  t[p].s:=a[l]; t[p].mx:=a[l]; t[p].mn:=a[l];
  exit;
 end;
 mid:=(l+r)>>1;
 build(l,mid,p<<1);
 build(mid+1,r,p<<1+1);
 pushup(p);
end;

procedure add1(l,r,x,y:longint;v:int64;p:longint);
var mid:longint;
begin
 pushdown(l,r,p);
 if (l>=x)and(r<=y) then
 begin
  add2(l,r,v,p);
  exit;
 end;
 mid:=(l+r)>>1;
 if x<=mid then add1(l,mid,x,y,v,p<<1);
 if y>mid then add1(mid+1,r,x,y,v,p<<1+1);
 pushup(p);
end;

procedure sqrt1(l,r,x,y,p:longint);
var mid:longint;
    s1,s2:int64;
begin
 pushdown(l,r,p);
 mid:=(l+r)>>1;
 if (l>=x)and(r<=y) then
 begin
  s1:=trunc(sqrt(t[p].mx));
  s2:=trunc(sqrt(t[p].mn));
  if s1=s2 then set1(l,r,s1,p)
   else if (s1-s2=1)and(t[p].mx-t[p].mn=1) then add2(l,r,s1-t[p].mx,p)
    else
    begin
     sqrt1(l,mid,x,y,p<<1);
     sqrt1(mid+1,r,x,y,p<<1+1);
     pushup(p);
    end;
  exit;
 end;
 if x<=mid then sqrt1(l,mid,x,y,p<<1);
 if y>mid then sqrt1(mid+1,r,x,y,p<<1+1);
 pushup(p);
end;

function query(l,r,x,y,p:longint):int64;
var mid:longint;
begin
 pushdown(l,r,p);
 if (l>=x)and(r<=y) then exit(t[p].s);
 mid:=(l+r)>>1;
 query:=0;
 if x<=mid then query:=query+query(l,mid,x,y,p<<1);
 if y>mid then query:=query+query(mid+1,r,x,y,p<<1+1);
 pushup(p);
end;

begin
 assign(input,'uoj228.in'); reset(input);
 assign(output,'uoj228.out'); rewrite(output);
 readln(n,m);
 for i:=1 to n do read(a[i]);
 build(1,n,1);
 for i:=1 to m do
 begin
  read(p);
  case p of
   1:
   begin
    read(x,y,z);
    add1(1,n,x,y,z,1);
   end;
   2:
   begin
    read(x,y);
    sqrt1(1,n,x,y,1);
   end;
   3:
   begin
    read(x,y);
    writeln(query(1,n,x,y,1));
   end;
  end;
 end;

 close(input);
 close(output);
end.