pku3661 Running

USACO月赛的银组题，dp性质比较明显，实现时有细节要注意

用f[i,j]表示第i分钟跑，疲劳度为j时的最远距离

  g[i,j]表示第i分钟休息，疲劳度为j时的最远距离

有f[i,j]=max{f[i-1,j-1]+d[i]   i>1 //上一秒跑

                   g[i-1,0]+d[i]    j=1 //上一秒刚休息到疲劳为零}

  g[i,j]=max{g[i-1,j+1]  j<m //上一秒休息

                   f[i-1,j+1]  j<m //上一秒跑

                   g[i-1,0]   j=0  //注意这个情况，体力为零时仍可以再休息}

program pku3661(input,output);
var
   h   : array[0..10001] of longint;
   f,g : array[0..10001,-1..501] of longint;
   n,m : longint;
procedure init;
var
   i : longint;
begin
   readln(n,m);
   for i:=1 to n do
      read(h[i]);
end; { init }
function max(aa,bb :longint ):longint;
begin
   if aa>bb then
      exit(aa);
   exit(bb);
end; { max }
function min(aa,bb :longint ):longint;
begin
   if aa<bb then
      exit(aa);
   exit(bb);
end; { min }
procedure main;
var
   i,j : longint;
begin
   fillchar(f,sizeof(f),0);
   fillchar(g,sizeof(g),0);
   for i:=1 to n do
      for j:=0 to m do
      begin
     if j>1 then
        f[i,j]:=max(f[i-1,j-1]+h[i],f[i,j]);    
     if j=1 then
        f[i,j]:=max(f[i,j],g[i-1,0]+h[i]);
     if j<=m-1 then
        g[i,j]:=max(g[i-1,j+1],f[i-1,j+1]);
     if j=0 then
        g[i,j]:=max(g[i-1,0],g[i,j]);
      end;
end; { main }
procedure print;
begin
   writeln(g[n,0]);
end; { print }
begin
   assign(input,'cowrun.in');reset(input);
   assign(output,'cowrun.out');rewrite(output);
   init;
   main;
   print;
   close(input);
   close(output);
end.