bzoj4826: [Hnoi2017]影魔

唯一一道赛场上a掉的题……

首先考虑第一种贡献。先不考虑两个相邻的情况，这个我们可以查询的时候直接加。首先预处理出第i个数左边离他最近的比他大的数的位置l[i]，以及右边的r[i]（这个可以用单调栈做，我用的树状数组），如果l[i]和r[i]存在，那么以第i个数为为他们最大值的点对只有(l[i],r[i])。这样的话点对数量是O(n)的，我们每次查询区间[L,R]的第一类贡献，除了相邻的情况，就是查询有多少个点对在[L ,R]之间，这个是个二维矩形求值可以主席树来轻松的维护。

对于第二种贡献，考虑一开始求出的l[i],r[i]数组。那么如果有l[i]<x<i，那么(x,r[i])一定是满足第二类贡献且他们之间最大值为a[i]（因为显然有x<a[i],a[i]<a[r[i]]）。对于i<x<r[i]也是一样的情况。那么我们单考虑r[i]的情况，对于查询[L,R]，就是查询所有l<=r[i]<=r的min(r[i],R)-max(l[i],L)，就是说对于我们每一个枚举的最大值，找到l[i],r[i]，在二维空间中覆盖两条线段(r[i],l[i]+1)到（r[i],i-1)和(l[i],i+1)到(l[i],r[i]-1)，查询的时候也是做一个二维矩形求值，这个也可可以主席树来做，相当于打个tag，不过最好不要下传做个标记永久化

然后就没有了，时间复杂度O(nlogn)，我没开int64也过了，数据都是随机的吧2333没有卡真是万幸

然后代码非常丑……考场上写了一半觉得写得不简洁就改改改……结果还是一大坨……

//orz lzz,you are our red sun
program j01;
const maxn=200086;
type node=record l,r,tag,sum:longint; end;
     opr=record l,r,ps:longint; end;
     opr1=record l,r,id:longint;end;
var f:array[0..80*maxn]of node;
    root1,root2:array[0..maxn]of longint;
    op1:array[0..maxn]of opr1;
    op:array[0..2*maxn]of opr;
    p,c:array[0..maxn]of longint;
    n,m,p1,p2,l,r,i,tt,inf,j,tot,ll,rr:longint;
    ans:int64;
    a:array[0..maxn]of longint;

function max(a,b:longint):longint;inline;
begin
    if a>b then exit(a) else exit(b);
end;

function min(a,b:longint):longint;inline;
begin
    if a<b then exit(a) else exit(b);
end;

procedure insmx(i,dd:longint);
begin
    while i<=n do
    begin
        c[i]:=max(c[i],dd);i:=i+(i and(-i));
    end;
end;

function askmx(i:longint):longint;
var tmp:longint;
begin
    tmp:=0;
    while i>0 do
    begin
        tmp:=max(tmp,c[i]);i:=i-(i and(-i));
    end;
    exit(tmp);
end;

procedure insmn(i,dd:longint);
begin
    while i<=n do
    begin
        c[i]:=min(c[i],dd);i:=i+(i and(-i));
    end;
end;

function askmn(i:longint):longint;
var tmp:longint;
begin
    tmp:=inf;
    while i>0 do
    begin
        tmp:=min(tmp,c[i]);i:=i-(i and(-i));
    end;
    exit(tmp);
end;
    
procedure sort1(l,r:longint);
var i,j,x:longint;y:opr1;
begin
    i:=l;j:=r;x:=op1[(i+j)div 2].l;
    repeat
        while op1[i].l<x do inc(i);
        while x<op1[j].l do dec(j);
        if i<=j then
        begin
            y:=op1[i];op1[i]:=op1[j];op1[j]:=y;
            inc(i);dec(j);
        end;
    until i>j;
    if i<r then sort1(i,r);
    if l<j then sort1(l,j);
end;

procedure sort(l,r:longint);
var i,j,x:longint;y:opr;
begin
    i:=l;j:=r;x:=op[(i+j)div 2].ps;
    repeat
        while op[i].ps<x do inc(i);
        while x<op[j].ps do dec(j);
        if i<=j then
        begin
            y:=op[i];op[i]:=op[j];op[j]:=y;
            inc(i);dec(j);
        end;
    until i>j;
    if i<r then sort(i,r);
    if l<j then sort(l,j);
end;

procedure ins1(var i:longint;l,r,ps:longint);
var mid:longint;
begin
    inc(tt);f[tt]:=f[i];i:=tt;
    inc(f[i].sum);if l=r then exit;
    mid:=(l+r)div 2;
    if ps<=mid then ins1(f[i].l,l,mid,ps) else ins1(f[i].r,mid+1,r,ps);
end;

procedure ins(var i:longint;l,r,ll,rr:longint);
var mid:longint;
begin
    inc(tt);f[tt]:=f[i];i:=tt;
    if(ll<=l)and(r<=rr)then
    begin
        inc(f[i].tag);inc(f[i].sum,r-l+1);
        exit;
    end;
    mid:=(l+r)div 2;
    if ll<=mid then ins(f[i].l,l,mid,ll,rr);
    if mid+1<=rr then ins(f[i].r,mid+1,r,ll,rr);
    f[i].sum:=f[i].tag*(r-l+1)+f[f[i].l].sum+f[f[i].r].sum;
end;
    
function ask(i,l,r,ll,rr:longint):longint;
var mid,tmp:longint;
begin
    if i=0 then exit(0);
    if(ll<=l)and(r<=rr)then exit(f[i].sum);
    tmp:=f[i].tag*(min(rr,r)-max(ll,l)+1);
    mid:=(l+r)div 2;
    if ll<=mid then tmp:=tmp+ask(f[i].l,l,mid,ll,rr);
    if mid+1<=rr then tmp:=tmp+ask(f[i].r,mid+1,r,ll,rr);
    exit(tmp);
end;

begin
    assign(input,'sf.in');reset(input);
    assign(output,'sf.out');rewrite(output);
    readln(n,m,p1,p2);
    for i:=1 to n do read(a[i]);
    for i:=1 to n do p[i]:=n-i+1;
    fillchar(c,sizeof(c),0);
    for i:=1 to n do
    begin
        op1[i].l:=askmx(p[a[i]]);op1[i].id:=i;
        insmx(p[a[i]],i);
    end;
    fillchar(c,sizeof(c),$3f);inf:=c[1];
    for i:=n downto 1 do
    begin
        op1[i].r:=askmn(p[a[i]]);
        insmn(p[a[i]],i);
    end;
    sort1(1,n);
    j:=1;while(op1[j].l=0)and(j<=n)do inc(j);
    fillchar(root1,sizeof(root1),0);
    fillchar(root2,sizeof(root2),0);
    for i:=1 to n do
    begin
        root1[i]:=root1[i-1];
        while(j<=n)and(op1[j].l<=i)do 
        begin
            if op1[j].r<inf then ins1(root1[i],1,n,op1[j].r);
            inc(j);
        end;
    end;
    tot:=0;
    for i:=1 to n do
    begin
        l:=op1[i].l+1;r:=op1[i].id-1;
        if (l<=r)and(op1[i].r<inf) then
        begin
            inc(tot);op[tot].ps:=op1[i].r;
            op[tot].l:=l;op[tot].r:=r;
        end;
        l:=op1[i].id+1;r:=min(n,op1[i].r-1);
        if (l<=r)and(op1[i].l>0) then
        begin
            inc(tot);op[tot].ps:=op1[i].l;
            op[tot].l:=l;op[tot].r:=r;
        end;
    end;
    sort(1,tot);
    j:=1;
    for i:=1 to n do
    begin
        root2[i]:=root2[i-1];
        while(j<=n)and(op[j].ps=i)do
        begin
            ins(root2[i],1,n,op[j].l,op[j].r);
            inc(j);
        end;
    end;
    for i:=1 to m do
    begin
        readln(l,r);
        ans:=int64(p1)*(ask(root1[r],1,n,l,r)-ask(root1[l-1],1,n,l,r)+(r-l));
        ans:=ans+int64(p2)*(ask(root2[r],1,n,l,r)-ask(root2[l-1],1,n,l,r));
        writeln(ans);
    end;
    close(input);close(output);
end.