poj1741 bzoj2152

树分治入门

poj1741是男人八题之一，经典的树分治的题目
这里用到的是点分治
核心思想是我们把某个点i作为根，把路径分为过点i和不过点i
先统计过点i这样的路径数，然后在统计其子树中的答案，这样就不断地划分成规模较小子问题。
要使划分最优，我们每次都选的是树的重心

type node=record
       len,next,po:longint;
     end;

var e:array[0..80010] of node;
    w,p,d,a,size:array[0..40010] of longint;
    v:array[0..40010] of boolean;
    root,sum,n,t,ans,k,i,x,y,z,len:longint;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure sort(l,r: longint);
  var i,j,x,y: longint;
  begin
    i:=l;
    j:=r;
    x:=a[(l+r) div 2];
    repeat
      while a[i]<x do inc(i);
      while x<a[j] do dec(j);
      if not(i>j) then
      begin
        y:=a[i];
        a[i]:=a[j];
        a[j]:=y;
        inc(i);
        j:=j-1;
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

procedure add(x,y,z:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].len:=z;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure getroot(x,fa:longint);  //选择重心
  var i,y:longint;
  begin
    i:=p[x];
    size[x]:=1;
    w[x]:=0;
    while i<>0 do
    begin
      y:=e[i].po;
      if (not v[y]) and (y<>fa) then
      begin
        getroot(y,x);
        size[x]:=size[x]+size[y];
        w[x]:=max(w[x],size[y]);
      end;
      i:=e[i].next;
    end;
    w[x]:=max(w[x],sum-size[x]);
    if w[x]<w[root] then root:=x;
  end;

procedure deep(x,fa:longint);
  var i,y:longint;
  begin
    inc(t);
    a[t]:=d[x];
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if not v[y] and (y<>fa) then
      begin
        d[y]:=d[x]+e[i].len;
        deep(y,x);
      end;
      i:=e[i].next;
    end;
  end;

function calc(x,now:longint):longint;
  var i,l,r:longint;
  begin
    t:=0;
    d[x]:=now;
    calc:=0;
    deep(x,0);
    sort(1,t);
    l:=1;
    r:=t;
    while l<r do
    begin
      if a[l]+a[r]<=k then
      begin
        calc:=calc+r-l;
        inc(l);
      end
      else dec(r);
    end;
  end;

procedure work(x:longint);
  var i,y:longint;
  begin
    ans:=ans+calc(x,0);  
    i:=p[x];
    v[x]:=true;
    while i<>0 do
    begin
      y:=e[i].po;
      if not v[y] then
      begin
        ans:=ans-calc(y,e[i].len);  //之前的计算会导致lca不为root的点对被算入，实际它们的路径不过重心，这里要减去
        sum:=size[y];
        root:=0;
        getroot(y,0);
        work(root);
      end;
      i:=e[i].next;
    end;
  end;

begin
  readln(n,k);
  while n<>0 do
  begin
    len:=0;
    fillchar(p,sizeof(p),0);
    for i:=1 to n-1 do
    begin
      readln(x,y,z);
      add(x,y,z);
      add(y,x,z);
    end;
    fillchar(v,sizeof(v),false);
    sum:=n;
    w[0]:=2147483647;
    getroot(1,0);
    ans:=0;
    work(root);
    writeln(ans);
    readln(n,k);
  end;
end.

 

bzoj2152是更水的树分治……