bzoj3530

比较恶心的题目
不难发现是在自动机上做数位dp
注意要考虑前导0，题目中给出的233是幸运数，20233不是
为此我非常猥琐的写了一个四维dp，用记忆化搜索实现

const mo=1000000007;
var dp:array[0..1,0..1,0..1205,0..1505] of longint;
    trie:array[0..2005,'0'..'9'] of longint;
    q,f:array[0..2005] of longint;
    can:array[0..2005] of boolean;
    ans,i,n,m,t,j,k,l:longint;
    s,ss:ansistring;
    ch:char;

procedure ac;
  var h,r,i,x,y:longint;
      c:char;
  begin
    h:=1;
    r:=0;
    for c:='0' to '9' do
      if trie[0,c]>0 then
      begin
        inc(r);
        q[r]:=trie[0,c];
      end;

    while h<=r do
    begin
      x:=q[h];
      for c:='0' to '9' do
        if trie[x,c]>0 then
        begin
          y:=trie[x,c];
          inc(r);
          q[r]:=y;
          j:=f[x];
          while (j>0) and (trie[j,c]=0) do j:=f[j];
          f[y]:=trie[j,c];
          if can[trie[j,c]] then can[y]:=true; //注意
        end;
      inc(h);
    end;
  end;

function calc(p,z,i,j:longint):longint; //p表示当前位置上的数是否需要小于N当前位上的数
                                        //z表示假如当前位出现0，是否是多余的0  
  var k,q,zz:longint;
      s,c,e:char;
  begin
    if can[j] then exit(0);
    if i=m then exit(1);
    if dp[p,z,i,j]<>-1 then exit(dp[p,z,i,j]);
    dp[p,z,i,j]:=0;
    if p=0 then e:=ss[i+1] else e:='9';
    for c:='0' to e do
    begin
      if (p=0) and (c=e) then q:=0
      else q:=1;
      k:=j;
      while k>-1 do
      begin
        if trie[k,c]>0 then break;
        k:=f[k];
      end;
      if k=-1 then k:=0 else k:=trie[k,c];
      if (z=0) and (c='0') then  //开头多余的0不考虑
      begin
        zz:=0;
        k:=0;  //多余的0不在自动机上匹配
      end
      else zz:=1;
      dp[p,z,i,j]:=(dp[p,z,i,j]+calc(q,zz,i+1,k)) mod mo;
    end;
    exit(dp[p,z,i,j]);
  end;

begin
  read(ch);
  while ch='0' do read(ch);
  readln(ss);
  ss:=ch+ss;
  m:=length(ss);
  f[0]:=-1;
  readln(n);
  for i:=1 to n do
  begin
    readln(s);
    j:=0;
    l:=length(s);
    for k:=1 to l do
    begin
      if trie[j,s[k]]=0 then
      begin
        inc(t);
        trie[j,s[k]]:=t;
      end;
      j:=trie[j,s[k]];
    end;
    can[j]:=true;
  end;
  ac;
  fillchar(dp,sizeof(dp),255);
  ans:=(calc(0,0,0,0)-1+mo) mod mo;
  writeln(ans);
end.