bzoj1449

竞赛图一般是把每场比赛当作一个点，然后和相应球队连边
每场比赛一赢一输对两支球队都有影响看起来不好搞
实际上我们可以先假设参加后面后面所有球队都输（每场比赛双输）
然后对每场比赛我们选择一支球队赢计算增加的收益，这样就很简单了
下面就是经典的平方流的做法

const inf=2147483647;
type node=record
       flow,next,cost,po:longint;
     end;

var e:array[0..400010] of node;
    q:array[0..1000010] of longint;
    s,a,b,l,w,p,cur,pre,d:array[0..6010] of longint;
    v:array[0..6010] of boolean;
    ans,len,i,j,x,y,n,m,t:longint;

procedure add(x,y,f,c:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].flow:=f;
    e[len].cost:=c;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure build(x,y,f,c:longint);
  begin
    add(x,y,f,c);
    add(y,x,0,-c);
  end;

function spfa:boolean;
  var x,y,i,f,r:longint;
  begin
    f:=1;
    r:=1;
    q[1]:=0;
    fillchar(v,sizeof(v),false);
    for i:=1 to t do
      d[i]:=inf;
    d[0]:=0;
    while f<=r do
    begin
      x:=q[f];
      v[x]:=false;
      i:=p[x];
      while i<>-1 do
      begin
        y:=e[i].po;
        if e[i].flow>0 then
          if d[y]>d[x]+e[i].cost then
          begin
            cur[y]:=i;
            pre[y]:=x;
            d[y]:=d[x]+e[i].cost;
            if not v[y] then
            begin
              inc(r);
              q[r]:=y;
              v[y]:=true;
            end;
          end;
        i:=e[i].next;
      end;
      inc(f);
    end;
    if d[t]=inf then exit(false) else exit(true);
  end;

function mincost:longint;
  var i,j:longint;
  begin
    mincost:=0;
    while spfa do
    begin
      mincost:=mincost+d[t];
      i:=t;
      while i<>0 do
      begin
        j:=cur[i];
        dec(e[j].flow);
        inc(e[j xor 1].flow);
        i:=pre[i];
      end;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n,m);
  for i:=1 to n do
    readln(w[i],l[i],a[i],b[i]);
  t:=n+m+1;
  for i:=1 to m do
  begin
    readln(x,y);
    inc(s[x]);
    inc(s[y]);
    build(0,i,1,0);
    build(i,x+m,1,0);
    build(i,y+m,1,0);
  end;
  for i:=1 to n do
  begin
    ans:=ans+a[i]*sqr(w[i])+b[i]*sqr(s[i]+l[i]);
    for j:=1 to s[i] do
      build(i+m,t,1,(a[i]+b[i])*(2*j-1)+2*w[i]*a[i]-2*b[i]*(s[i]+l[i]));
  end;
  writeln(mincost+ans);
end.