bzoj2730

首先不难想到要先求割顶，求割顶的方法白书上有讲解
由于是一个矿崩塌，所以假如一个连通块连接了两个以上割顶，那么这个连通块内显然是不用设出口的
连接块只连接了一个割顶，那么出口可以设在这个连通块内任意位置
由此我们可以把两个问题解决了
注意特判一种情况，当不存在割顶的时候，至少要设两个出口

type node=record
       po,next:longint;
     end;

var w:array[0..500010] of node;
    dfn,low,mark,cs,s,p:array[0..510] of longint;
    v,cut:array[0..510] of boolean;
    task,tot,t,i,x,y,len,n,m:longint;
    ans:int64;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y:longint);
  begin
    inc(len);
    w[len].po:=y;
    w[len].next:=p[x];
    p[x]:=len;
  end;

procedure dfs(x,fa:longint);
  var i,y,ch:longint;
  begin
    inc(t);
    dfn[x]:=t;
    low[x]:=t;
    i:=p[x];
    ch:=0;
    while i<>-1 do
    begin
      y:=w[i].po;
      if dfn[y]=0 then
      begin
        dfs(y,x);
        inc(ch);
        low[x]:=min(low[x],low[y]);
        if low[y]>=dfn[x] then cut[x]:=true;  //只要有子树不能连回当前点的祖先
      end
      else if (dfn[y]<dfn[x]) and (fa<>y) then  //注意fa<>y
        low[x]:=min(low[x],dfn[y]);
      i:=w[i].next;
    end;
    if (fa<0) and (ch=1) then cut[x]:=false; //注意单链的首位不是割顶
  end;

procedure color(x:longint);
  var i,y:longint;
  begin
    i:=p[x];
    v[x]:=true;
    inc(s[t]);
    while i<>-1 do
    begin
      y:=w[i].po;
      if not v[y] then
      begin
        if not cut[y] then color(y)
        else if mark[y]<>t then
        begin
          mark[y]:=t;
          inc(cs[t]);
        end;
      end;
      i:=w[i].next;
    end;
  end;

begin
  readln(m);
  while m<>0 do
  begin
    inc(task);
    len:=-1;
    fillchar(p,sizeof(p),255);
    n:=0;
    for i:=1 to m do
    begin
      readln(x,y);
      add(x,y);
      add(y,x);
      if x>n then n:=x;
      if y>n then n:=y;
    end;
    fillchar(dfn,sizeof(dfn),0);
    fillchar(cut,sizeof(cut),false);
    for i:=1 to n do
      if dfn[i]=0 then
      begin
        t:=0;
        dfs(i,-1);
      end;
    ans:=1;
    t:=0;
    tot:=0;
    fillchar(v,sizeof(v),false);
    fillchar(mark,sizeof(mark),0);
    fillchar(cs,sizeof(cs),0);
    for i:=1 to n do
      if not v[i] and not cut[i] then
      begin
        inc(t);
        s[t]:=0;
        color(i);
        if cs[t]=1 then
        begin
          inc(tot);
          ans:=ans*int64(s[t]);
        end;
      end;
    if t=1 then  //特判
    begin
      tot:=2;
      ans:=n*(n-1) div 2;
    end;
    writeln('Case ',task,': ',tot,' ',ans);
    readln(m);
  end;
end.