bzoj3275

容易想到是最小割（最大权独立集）
然后每个数拆成两个点，不能同时选的之间连边跑最小割，
最后答案=总数-mincut/2 因为这样建图将流量变成了原来的两倍

当然这道题更好的建图方法是分成奇数和偶数两个集合
不难发现，奇数和奇数，偶数和偶数之间显然不能同时满足条件的
所以这样直接ans=总点数-mincut

const inf=100000007;
type node=record
       point,flow,next:longint;
     end;

var edge:array[0..2000010] of node;
    a,p,cur,pre,d,numh,h:array[0..6010] of longint;
    s,i,j,n,t,len:longint;
    x:double;

function gcd(a,b:longint):longint;
  begin
    if b=0 then exit(a)
    else exit(gcd(b,a mod b));
  end;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,f:longint);
  begin
    inc(len);
    edge[len].point:=y;
    edge[len].flow:=f;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

function sap:longint;
  var q,u,i,j,neck,tmp:longint;
  begin
    sap:=0;
    u:=0;
    numh[0]:=t+1;
    for i:=0 to t do
      cur[i]:=p[i];
    neck:=inf;
    while h[0]<t+1 do
    begin
      d[u]:=neck;
      i:=cur[u];
      while i<>-1 do
      begin
        j:=edge[i].point;
        if (edge[i].flow>0) and (h[u]=h[j]+1) then
        begin
          pre[j]:=u;
          cur[u]:=i;
          neck:=min(neck,edge[i].flow);
          u:=j;
          if u=t then
          begin
            sap:=sap+neck;
            while u<>0 do
            begin
              u:=pre[u];
              j:=cur[u];
              dec(edge[j].flow,neck);
              inc(edge[j xor 1].flow,neck);
            end;
            neck:=inf;
          end;
          break;
        end;
        i:=edge[i].next;
      end;
      if i=-1 then
      begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then exit;
        tmp:=t;
        i:=p[u];
        q:=-1;
        while i<>-1 do
        begin
          j:=edge[i].point;
          if edge[i].flow>0 then
            if h[j]<tmp then
            begin
              tmp:=h[j];
              q:=i;
            end;
          i:=edge[i].next;
        end;
        h[u]:=tmp+1;
        inc(numh[h[u]]);
        cur[u]:=q;
        if u<>0 then
        begin
          u:=pre[u];
          neck:=d[u];
        end;
      end;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n);
  t:=2*n+1;
  for i:=1 to n do
  begin
    read(a[i]);
    add(0,i,a[i]);
    add(i,0,0);
    add(i+n,t,a[i]);
    add(t,i+n,0);
    s:=s+a[i];
  end;
  for i:=1 to n-1 do
    for j:=i+1 to n do
    begin
      x:=sqrt(sqr(a[i])+sqr(a[j]));
      if (gcd(a[i],a[j])=1) and (x=trunc(x)) then
      begin
        add(i,j+n,inf);
        add(j+n,i,0);
        add(j,i+n,inf);
        add(i+n,j,0);
      end;
    end;
  writeln(s-sap div 2);
end.