bzoj1787

首先考虑两个点的最优集合点，必然是在这两点间最短路径上

三个点的最优集合点，不难猜测，是在两两之间的LCA上取，

那到底取哪个呢？有一个偷懒的思维方法

由于最后的最优集合点唯一，如果有两个LCA相等，则一定是另外一个

当然事实也是这样

选定了集合点之后，设选的是a，b的LCA，ab到集合点的距离在LCA中可以求出，

但c点到集合点的距离呢？还要再做一次LCA……

所以比较烦

type link=^node;
     node=record
       po:longint;
       next:link;
     end;
     point=^ask;
     ask=record
       po,num:longint;
       next:point;
     end;

var a:array[0..2000010] of point;
    w:array[0..500010] of link;
    al,b,d,fa,loc:array[0..500010] of longint;
    ans:array[0..2000010] of longint;
    c:array[0..500010,0..3] of longint;
    v:array[0..500010] of boolean;
    n,m,i,j,x,y,z:longint;

procedure add(x,y:longint);
  var p:link;
  begin
    new(p);
    p^.po:=y;
    p^.next:=w[x];
    w[x]:=p;
  end;

procedure que(x,y,p:longint);
  var q:point;
  begin
    new(q);
    q^.num:=p;
    q^.po:=y;
    q^.next:=a[x];
    a[x]:=q;
  end;

function getf(x:longint):longint;
  begin
    if fa[x]<>x then fa[x]:=getf(fa[x]);
    exit(fa[x]);
  end;

procedure lca(x:longint);
  var p:link;
      q,pre:point;
      y,e:longint;
  begin
    p:=w[x];
    v[x]:=true;
    while p<>nil do
    begin
      y:=p^.po;
      if not v[y] then
      begin
        d[y]:=d[x]+1;
        lca(y);
        fa[y]:=x;
      end;
      p:=p^.next;
    end;
    q:=a[x];
    while q<>nil do
    begin
      y:=q^.po;
      if v[y] and (ans[q^.num]=0) then ans[q^.num]:=getf(y);
      pre:=q;
      q:=q^.next;
      dispose(pre);
    end;
  end;

function get(i:longint):longint;
  begin
    if al[i]=1 then
      exit(d[c[i,2]]+d[c[i,3]]-2*d[loc[i]]+d[loc[i]]+d[c[i,1]]-2*d[ans[i]])
    else if al[i]=2 then
      exit(d[c[i,1]]+d[c[i,3]]-2*d[loc[i]]+d[loc[i]]+d[c[i,2]]-2*d[ans[i]])
    else exit(d[c[i,1]]+d[c[i,2]]-2*d[loc[i]]+d[loc[i]]+d[c[i,3]]-2*d[ans[i]]);
  end;

begin
  readln(n,m);
  for i:=1 to n-1 do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
  end;
  for i:=1 to n do
    fa[i]:=i;
  for i:=1 to m do
  begin
    readln(x,y,z);
    c[i,1]:=x;
    c[i,2]:=y;
    c[i,3]:=z;
    que(x,y,i);
    que(y,x,i);
    que(y,z,i+m);
    que(z,y,i+m);
    que(x,z,i+2*m);
    que(z,x,i+2*m);
  end;
  d[1]:=0;
  lca(1);
  for i:=1 to n do
  begin
    fa[i]:=i;
    a[i]:=nil;
    v[i]:=false;
    d[i]:=0;
  end;
  for i:=1 to m do
  begin
    if ans[i]=ans[i+m] then
    begin
      loc[i]:=ans[i+2*m];
      al[i]:=2;
      que(loc[i],c[i,2],i);
      que(c[i,2],loc[i],i);
    end
    else if ans[i]=ans[i+2*m] then
    begin
      loc[i]:=ans[i+m];
      al[i]:=1;
      que(loc[i],c[i,1],i);
      que(c[i,1],loc[i],i);
    end
    else begin
      loc[i]:=ans[i];
      al[i]:=3;
      que(loc[i],c[i,3],i);
      que(c[i,3],loc[i],i);
    end;
    ans[i]:=0;
  end;
  lca(1);
  for i:=1 to m do
    writeln(loc[i],' ',get(i));
end.