bzoj1055

不难想到是一个布尔型dp，

不难想到用f[i,j,k]表示区间[i,j]能否变为字母k

不难想到对于f[i,j,k]，拆[i,j]成两个区间，然后穷举k的每一个变换来判断

感觉记忆化搜索写的比较顺，就写了记忆化

const a:array[1..4] of char=('W','I','N','G');

var b:array[0..300] of longint;
    f:array[0..300,0..300,0..4] of integer;
    w:array[0..4,0..20] of longint;
    c:array[1..5] of longint;
    l,i,j,k,e,n,m,p:longint;
    flag:boolean;
    s:string;

function exc(x:char):longint;
  begin
    if x='W' then exit(1)
    else if x='I' then exit(2)
    else if x='N' then exit(3)
    else if x='G' then exit(4);
  end;

function search(l,r,k:longint):integer;
  var i,j,x1,x2:longint;
  begin
    if f[l,r,k]<>0 then exit(f[l,r,k]);
    if l=r then
    begin
      f[l,l,b[l]]:=1;
      if k=b[l] then exit(1)
      else begin
        f[l,l,k]:=-1;
        exit(-1);
      end;
    end;
    for i:=1 to c[k] do
    begin
      x1:=(w[k,i]-1) div 4+1;
      x2:=(w[k,i]-1) mod 4+1;
      for j:=l to r-1 do
      begin
        if (search(l,j,x1)=1) and (search(j+1,r,x2)=1) then
        begin
          f[l,r,k]:=1;
          exit(1);
        end;
      end;
    end;
    f[l,r,k]:=-1;
    exit(-1);
  end;

begin
  for i:=1 to 4 do
    read(c[i]);
  readln;
  for i:=1 to 4 do
    for j:=1 to c[i] do
    begin
      readln(s);
      p:=(exc(s[1])-1)*4+exc(s[2]);
      w[i,j]:=p;
    end;

  readln(s);
  n:=length(s);

  for i:=1 to n do
    b[i]:=exc(s[i]);

  flag:=false;
  for i:=1 to 4 do
    if search(1,n,i)=1 then
    begin
      write(a[i]);
      flag:=true;
    end;
  if not flag then writeln('The name is wrong!') else writeln;
end.