bzoj1042

首先直接做多重背包肯定会TLE的，

观察这个背包问题有什么特殊性呢

物品种类和重量，价值是一定的，不同的是背包的容量和物品的数量

由于当物品数量没有限制的时候，方案数是可以预处理出来的

所以我们考虑用ans=物品数量没有限制时的方案数-物品超出限制的方案数来解决

第一部分是可以用完全背包来解决的

第二问不难想到用容斥原理来解决

设f[m]为容量为m时的方案数

假如当i号物品超出数量s[i]限制（不知道其他物品有没有超），方案数f[m-w[i]*(s[i]+1)]（严格超出限制

以此类推，可得出多个物品超出限制的方案数

根据容斥原理，计算一下即可

var f:array[0..100010] of int64;
    w:array[1..4] of longint;
    c:array[0..1010,0..4] of longint;
    t:array[0..1010] of longint;
    i,n,j,k,p,y,m,s:longint;
    ans:int64;

begin
  for i:=1 to 4 do
    read(w[i]);
  readln(n);
  for i:=1 to n do
  begin
    for j:=1 to 4 do
      read(c[i,j]);
    readln(t[i]);
    if t[i]>m then m:=t[i];
  end;
  f[0]:=1;
  for i:=1 to 4 do
    for j:=w[i] to 100000 do
      f[j]:=f[j]+f[j-w[i]];

  for i:=1 to n do
  begin
    ans:=0;
    for j:=0 to 15 do   //用二进制表示物品是否超出限制
    begin
      s:=t[i];
      y:=0;
      for k:=1 to 4 do
      begin
        p:=1 shl (k-1);
        if j and p<>0 then
        begin
          s:=s-w[k]*(c[i,k]+1);
          if s<0 then break;
          inc(y);
        end;
      end;
      if s<0 then continue;   //注意可能不存在某几个物品都超出限制的情况
      if y mod 2=1 then ans:=ans-f[s] else ans:=ans+f[s];
    end;
    writeln(ans);
  end;
end.