bzoj1237

假如不存在相等的两个数不能配对，那很容易贪心得到，A中rank 1匹配B中rank 1

A中rank2 匹配B中rank 2……

有了相等不能匹配这个条件，那么A中rank i可能和rank i,i-1,i+1匹配

也有可能三对数字交换匹配

dp一下就好了

const inf=2000010;
type node=array[0..100010] of longint;
var a,b:node;
    f:array[0..100010] of int64;
    n,i:longint;

function min(a,b:int64):int64;
  begin
    if a>b then exit(b) else exit(a);
  end;

function calc(a,b:longint):longint;
  begin
    if a=b then exit(inf)
    else exit(abs(a-b));
  end;

procedure qsort(var a:node);
  procedure sort(l,r:longint);
    var i,j,x,y: longint;
    begin
      i:=l;
      j:=r;
      x:=a[(l+r) div 2];
      repeat
        while a[i]<x do inc(i);
        while x<a[j] do dec(j);
        if not(i>j) then
        begin
          y:=a[i];
          a[i]:=a[j];
          a[j]:=y;
          inc(i);
          j:=j-1;
        end;
      until i>j;
      if l<j then sort(l,j);
      if i<r then sort(i,r);
    end;

  begin
    sort(1,n);
  end;

begin
  readln(n);
  for i:=1 to n do
    readln(a[i],b[i]);
  qsort(a);
  qsort(b);
  f[1]:=calc(a[1],b[1]);
  f[2]:=min(f[1]+calc(a[2],b[2]),calc(a[1],b[2])+calc(a[2],b[1]));
  for i:=3 to n do
  begin
    f[i]:=f[i-1]+calc(a[i],b[i]);
    f[i]:=min(f[i],f[i-2]+calc(a[i-1],b[i])+calc(a[i],b[i-1]));
    f[i]:=min(f[i],f[i-3]+calc(a[i],b[i-2])+calc(a[i-1],b[i])+calc(a[i-2],b[i-1]));
    f[i]:=min(f[i],f[i-3]+calc(a[i],b[i-1])+calc(a[i-1],b[i-2])+calc(a[i-2],b[i]));
  end;
  if f[n]=inf then writeln(-1) else writeln(f[n]);
end.