bzoj2565

网络流就先告一段落了

在进行其他训练之前，我决定先练一道后缀数组（对这个我还是比较有自信的）

虽然之前没用后缀数组解决过回文问题，但是稍微想想就知道，

要解决最长双倍回文，首先要解决最长回文序列，

要解决最长回文序列，首先要倒序添加原串然后LCP

任意两个后缀的LCP我就不多说了，

然后我们就可以求出以任意一个字符为中心展开的最长回文串（要小心，偶数长度的最长回文串）

然后就能求出每个字符向左向右延伸回文串能延伸多远，

最后在遍历一边就可以了。

var h,sa,rank,x,y,sum:array[0..210000] of longint;
    f:array[0..200010,0..20] of longint;
    d:array[0..20] of longint;
    left,right:array[0..100010] of longint;
    p,i,j,l,n,m,ans,t:longint;
    s:ansistring;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure suffix;
  var m,p,i,j:longint;
  begin
    for i:=1 to n do
    begin
      y[i]:=ord(s[i]);
      inc(sum[y[i]]);
    end;
    m:=255;
    for i:=2 to m do
      inc(sum[i],sum[i-1]);
    for i:=n downto 1 do
    begin
      sa[sum[y[i]]]:=i;
      dec(sum[y[i]]);
    end;
    p:=1;
    rank[sa[1]]:=1;
    for i:=2 to n do
    begin
      if y[sa[i]]<>y[sa[i-1]] then inc(p);
      rank[sa[i]]:=p;
    end;
    m:=p;
    j:=1;
    while m<n do
    begin
      y:=rank;
      fillchar(sum,sizeof(sum),0);
      p:=0;
      for i:=n-j+1 to n do
      begin
        inc(p);
        x[p]:=i;
      end;
      for i:=1 to n do
        if sa[i]>j then
        begin
          inc(p);
          x[p]:=sa[i]-j;
        end;
      for i:=1 to n do
      begin
        rank[i]:=y[x[i]];
        inc(sum[rank[i]]);
      end;
      for i:=2 to m do
        inc(sum[i],sum[i-1]);
      for i:=n downto 1 do
      begin
        sa[sum[rank[i]]]:=x[i];
        dec(sum[rank[i]]);
      end;
      p:=1;
      rank[sa[1]]:=1;
      for i:=2 to n do
      begin
        if (y[sa[i]]<>y[sa[i-1]]) or (y[sa[i]+j]<>y[sa[i-1]+j]) then inc(p);
        rank[sa[i]]:=p;
      end;
      m:=p;
      j:=j shl 1;
    end;
    h[1]:=0;
    p:=0;
    for i:=1 to n do
    begin
      if rank[i]=1 then continue;
      j:=sa[rank[i]-1];
      while s[i+p]=s[j+p] do inc(p);
      h[rank[i]]:=p;
      if p>0 then dec(p);
    end;
  end;

procedure rmq;
  begin
    t:=trunc(ln(n)/ln(2));
    d[0]:=1;
    for i:=1 to t do
      d[i]:=d[i-1]*2;

    for i:=1 to n do
      f[i,0]:=h[i];
    for j:=1 to t do
      for i:=1 to n do
        if (i+d[j]-1<=n) then
          f[i,j]:=min(f[i,j-1],f[i+d[j-1],j-1]);
  end;

function ask(x,y:longint):longint;
  var k:longint;
  begin
    if x>y then swap(x,y);
    inc(x);
    k:=trunc(ln(y-x+1)/ln(2));
    ask:=min(f[x,k],f[y-d[k]+1,k]);
  end;

begin
  readln(s);
  l:=length(s);
  s:=s+'*';
  for i:=l downto 1 do
  begin
    s:=s+s[i];
    left[i]:=1;
    right[i]:=1;
  end;
  n:=length(s);
  suffix;
  rmq;
  for i:=1 to l do
  begin
    p:=ask(rank[i],rank[n+1-i]);  //先求奇数长度的回文序列
    left[i-p+1]:=max(left[i-p+1],p*2-1);
    right[i+p-1]:=max(right[i+p-1],p*2-1);
    if i<>l then
    begin
      p:=ask(rank[i],rank[n-i]);  //偶数长度的回文序列
      if p>1 then dec(p);    //细节
      if p<>0 then
      begin
        left[i-p+1]:=max(left[i-p+1],2*p);
        right[i+p]:=max(right[i+p],2*p);
      end;
    end;
  end;
  for i:=l-1 downto 1 do  //处理每个字符为回文串的一端的最远延伸
    right[i]:=max(right[i],right[i+1]-2);
  for i:=2 to l do
    left[i]:=max(left[i],left[i-1]-2);
  for i:=1 to l-1 do  //不难理解
    ans:=max(ans,right[i]+left[i+1]);
  writeln(ans);
end.